dccaldatechkleapyear.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Youhei SASAKI, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2009-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Judge whether it is a leap year
!> @details
!> Procedures described in this file are provided from "dc_calendar" module.
!> @enden
!>
!> @ja
!> @brief 閏年かどうかの判定
!> @details
!> このファイルに記載される手続き群は dc_calendar モジュールから提供されます.
!> @endja
!>
 
!> @en
!> @brief Judge whether the specified date is in a leap year
!> @details
!> Judge whether it is a leap year.
!>
!> If an optional argument `date` is omitted,
!> information of date that is stored in the "dc_calendar"
!> is used as date of origin.
!> If `date` is not omitted, information of the variable is used as
!> date of origin.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed seconds `elapse_sec` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] elapse_sec Elapsed seconds from `date`
!> @param[in] date An object that stores information of date of origin
!> @param[in] cal An object that stores information of calendar
!> @return .true. if leap year, .false. otherwise
!> @enden
!>
!> @ja
!> @brief 指定された日時が閏年かどうかを判定
!> @details
!> 閏年かどうかの判定.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される日時が起点の日時として用いられます.
!> `date` が省略されない場合にはその変数に設定された日時が
!> 起点の日時として用いられます.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過秒数 `elapse_sec`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] elapse_sec `date` からの経過秒数
!> @param[in] date 起点となる日時情報を収めたオブジェクト
!> @param[in] cal 暦情報を収めたオブジェクト
!> @return 閏年であれば .true., そうでなければ .false.
!> @endja
function dccaldatechkleapyear1( elapse_sec, date, cal ) result(result)
 
  use dc_calendar_types, only: dc_cal_date, dc_cal, &
    & cal_julian, cal_gregorian
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize, dccaldate_ym2d
  use dc_calendar_generic, only: dccaldateinquire
  use dc_types, only: dp
  implicit none
  logical:: result
  real(dp), intent(in):: elapse_sec
  type(dc_cal_date), intent(in), optional, target:: date
  type(dc_cal), intent(in), optional, target:: cal
 
  ! 作業変数
  ! Work variables
  !
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  integer:: year, month, day, hour, min
  real(dp):: sec
continue
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  result = .false.
  if ( .not. datep % initialized ) return
  if ( .not. calp % initialized ) return
 
  ! 経過時間を与えた場合の日時を取得
  ! Inquire date and time when elapse time is given
  !
  call dccaldateinquire( year, month, day, hour, min, sec, & ! (out)
    & elapse_sec = elapse_sec, date = datep , cal = calp )   ! (in)
 
  ! 閏年の判定
  ! Judge leap year
  !
  select case( calp % cal_type )
  case( cal_julian )
    if ( mod( year, 4 ) == 0 ) then
      result = .true.
    else
      result = .false.
    end if
 
  case( cal_gregorian )
    if ( mod( year, 400 ) == 0 ) then
      result = .true.
    elseif ( mod( year, 100 ) == 0 ) then
      result = .false.
    elseif ( mod( year, 4 ) == 0 ) then
      result = .true.
    else
      result = .false.
    end if
 
  case default
    result = .false.
  end select
 
end function dccaldatechkleapyear1