dccalconvertbyunit.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Youhei SASAKI, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2009-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Unit conversion functions for calendar
!> @details
!> Procedures described in this file are provided from "dc_calendar" module.
!> @enden
!>
!> @ja
!> @brief 暦の単位変換関数
!> @details
!> このファイルに記載される手続き群は dc_calendar モジュールから提供されます.
!> @endja
!>
 
!> @en
!> @brief Convert time value between different units (string version)
!> @details
!> Convert of unit.
!>
!> Valid strings as units of time are follows.
!>
!> | Parameter                      | Description       |
!> |--------------------------------|-------------------|
!> | dc_calendar_types#UNIT_SEC     | Units of second   |
!> | dc_calendar_types#UNIT_MIN     | Units of minute   |
!> | dc_calendar_types#UNIT_HOUR    | Units of hour     |
!> | dc_calendar_types#UNIT_DAY     | Units of day      |
!>
!> If an optional argument `cal` is omitted,
!> unit is converted with information of a calendar
!> that is stored in the "dc_calendar".
!> If `cal` is not omitted, unit is converted with information of the variable.
!>
!> @param[in] in_time Numerical value of time before conversion
!> @param[in] in_unit Units of time before conversion (string)
!> @param[in] out_unit Units of time after conversion (string)
!> @param[in] cal An object that stores information of calendar
!> @return Numerical value of time after conversion
!> @enden
!>
!> @ja
!> @brief 時間値を異なる単位間で変換 (文字列版)
!> @details
!> 単位の変換を行います.
!>
!> 時間の単位として有効な文字列については以下を参照下さい.
!>
!> | パラメータ                     | 説明              |
!> |--------------------------------|-------------------|
!> | dc_calendar_types#UNIT_SEC     | 秒の単位          |
!> | dc_calendar_types#UNIT_MIN     | 分の単位          |
!> | dc_calendar_types#UNIT_HOUR    | 時間の単位        |
!> | dc_calendar_types#UNIT_DAY     | 日の単位          |
!>
!> 省略可能引数 `cal` が省略された場合には, dc_calendar 内部で
!> 保持される暦に関する情報を用いた単位の変換が行われます.
!> `cal` が省略されない場合にはその変数に設定された暦の情報を
!> 用いて単位の変換が行われます.
!>
!> @param[in] in_time 変換前の時間の数値
!> @param[in] in_unit 変換前の時間の単位 (文字列)
!> @param[in] out_unit 変換後の時間の単位 (文字列)
!> @param[in] cal 暦情報を収めたオブジェクト
!> @return 変換後の時間の数値
!> @endja
function dccalconvertbyunit1( in_time, in_unit, out_unit, cal ) result( out_time )
 
  use dc_calendar_internal, only: default_cal, default_cal_set, &
    & dccaldate_str2usym
  use dc_calendar_types, only: dc_cal
  use dc_calendar_generic, only: dccalconvertbyunit
  use dc_message, only: messagenotify
  use dc_types, only: dp
  implicit none
  real(dp):: out_time
  real(dp), intent(in):: in_time
  character(*), intent(in):: in_unit
  character(*), intent(in):: out_unit
  type(dc_cal), intent(in), optional, target:: cal
 
  ! 作業変数
  ! Work variables
  !
  type(dc_cal), pointer:: calp =>null()
  integer:: in_unit_sym, out_unit_sym
  character(*), parameter:: subname = 'DCCalConvertByUnit1'
continue
 
  out_time = -1.0
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  if ( .not. calp % initialized ) then
    call messagenotify('W', subname, '"cal" is not initialized. <-1> is returned.' )
    goto 999
  end if
 
  ! 単位の解釈
  ! Parse units
  !
  in_unit_sym  = dccaldate_str2usym( in_unit )
  out_unit_sym = dccaldate_str2usym( out_unit )
 
  ! 数値の変換
  ! Convert a value
  !
  out_time = dccalconvertbyunit( in_time, in_unit_sym, out_unit_sym, cal )
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp )
end function dccalconvertbyunit1
 
!---------------------------------------------------------------------
 
!> @en
!> @brief Convert time value between different units (symbol version)
!> @details
!> Convert of unit.
!>
!> Valid integer variables as units of time are follows.
!> Do not specify integer directly, but specify following variables.
!>
!> | Parameter                           | Description       |
!> |-------------------------------------|-------------------|
!> | dc_calendar_types#UNIT_SYMBOL_SEC   | Units of second   |
!> | dc_calendar_types#UNIT_SYMBOL_MIN   | Units of minute   |
!> | dc_calendar_types#UNIT_SYMBOL_HOUR  | Units of hour     |
!> | dc_calendar_types#UNIT_SYMBOL_DAY   | Units of day      |
!>
!> If an optional argument `cal` is omitted,
!> unit is converted with information of a calendar
!> that is stored in the "dc_calendar".
!> If `cal` is not omitted, unit is converted with information of the variable.
!>
!> @param[in] in_time Numerical value of time before conversion
!> @param[in] in_unit Units of time before conversion (integer symbol)
!> @param[in] out_unit Units of time after conversion (integer symbol)
!> @param[in] cal An object that stores information of calendar
!> @return Numerical value of time after conversion
!> @enden
!>
!> @ja
!> @brief 時間値を異なる単位間で変換 (シンボル版)
!> @details
!> 単位の変換を行います.
!>
!> 時間の単位として有効な整数型変数については以下を参照下さい.
!> 単位として整数値を直接与えることはせず, 以下の変数を与えてください.
!>
!> | パラメータ                          | 説明              |
!> |-------------------------------------|-------------------|
!> | dc_calendar_types#UNIT_SYMBOL_SEC   | 秒の単位          |
!> | dc_calendar_types#UNIT_SYMBOL_MIN   | 分の単位          |
!> | dc_calendar_types#UNIT_SYMBOL_HOUR  | 時間の単位        |
!> | dc_calendar_types#UNIT_SYMBOL_DAY   | 日の単位          |
!>
!> 省略可能引数 `cal` が省略された場合には, dc_calendar 内部で
!> 保持される暦に関する情報を用いた単位の変換が行われます.
!> `cal` が省略されない場合にはその変数に設定された暦の情報を
!> 用いて単位の変換が行われます.
!>
!> @param[in] in_time 変換前の時間の数値
!> @param[in] in_unit 変換前の時間の単位 (整数シンボル)
!> @param[in] out_unit 変換後の時間の単位 (整数シンボル)
!> @param[in] cal 暦情報を収めたオブジェクト
!> @return 変換後の時間の数値
!> @endja
function dccalconvertbyunit2( in_time, in_unit, out_unit, cal ) result( out_time )
 
  use dc_calendar_internal, only: default_cal, default_cal_set
  use dc_calendar_types, only: dc_cal, &
    & unit_symbol_day, unit_symbol_hour, unit_symbol_min, unit_symbol_sec
  use dc_message, only: messagenotify
  use dc_types, only: dp
  implicit none
  real(dp):: out_time
  real(dp), intent(in):: in_time
  integer, intent(in):: in_unit
  integer, intent(in):: out_unit
  type(dc_cal), intent(in), optional, target:: cal
 
  ! 作業変数
  ! Work variables
  !
  type(dc_cal), pointer:: calp =>null()
  real(dp):: in_timew
  character(*), parameter:: subname = 'DCCalConvertByUnit2'
continue
 
  out_time = -1.0
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  if ( .not. calp % initialized ) then
    call messagenotify('W', subname, '"cal" is not initialized. <-1> is returned.' )
    goto 999
  end if
 
  ! 数値の変換
  ! Convert a value
  !
  select case(in_unit)
  case(unit_symbol_day)
    in_timew = in_time * calp % hour_in_day &
      &                * calp % min_in_hour &
      &                * calp % sec_in_min
  case(unit_symbol_hour)
    in_timew = in_time * calp % min_in_hour &
      &                * calp % sec_in_min
  case(unit_symbol_min)
    in_timew = in_time * calp % sec_in_min
  case(unit_symbol_sec)
    in_timew = in_time
  case default
    call messagenotify('W', subname, 'in_unit=<%d> is invalid. (ONLY day,hour,min,sec are valid).'  // &
      & ' <-1> is returned.', &
      & i = (/ in_unit /) )
    goto 999
  end select
 
  select case(out_unit)
  case(unit_symbol_day)
    out_time = in_timew / calp % hour_in_day &
      &                 / calp % min_in_hour &
      &                 / calp % sec_in_min
  case(unit_symbol_hour)
    out_time = in_timew / calp % min_in_hour &
      &                 / calp % sec_in_min
  case(unit_symbol_min)
    out_time = in_timew / calp % sec_in_min
  case(unit_symbol_sec)
    out_time = in_timew
  case default
    call messagenotify('W', subname, 'out_unit=<%d> is invalid. (ONLY day,hour,min,sec are valid).'  // &
      & ' <-1> is returned.', &
      & i = (/ out_unit /) )
    goto 999
  end select
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp )
end function dccalconvertbyunit2