sysdep.f90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Youhei SASAKI, Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Provides interface for system dependent procedures
!> @details
!> This module provides interfaces for system dependent procedures.
!> In other words, there are interface declarations of functions and
!> subroutines whose features are regarded as system dependent.
!>
!> Note that a procedure with one name may have several implementations.
!>
!> The sysdep module has no dependence to other modules.
!>
!> @section sysdep_procedures Procedures list
!>
!> | Procedure       | Description                          |
!> |-----------------|--------------------------------------|
!> | AbortProgram    | Abort program execution              |
!> | SysdepArgGet    | Get command line argument            |
!> | SysdepArgCount  | Get number of command line arguments |
!> | SysdepEnvGet    | Get environment variable             |
!>
!> @enden
!>
!> @ja
!> @brief システムに依存する手続きのインタフェースを提供します
!> @details
!> このモジュールはシステムに依存する手続きに関する
!> インタフェースを提供します.
!> 言い換えると, このモジュールではシステムに依存するサブルーチンと関数の
!> インタフェース宣言がなされています.
!>
!> 従って, ある名前の手続きがあったとして, その手続きの実装は実際には
!> 複数のファイルにおいて行われている可能性があるので気をつけてください.
!>
!> この sysdep モジュールは他のモジュールに依存しません.
!>
!> @section sysdep_procedures_ja 手続一覧
!>
!> | 手続名          | 説明                                 |
!> |-----------------|--------------------------------------|
!> | AbortProgram    | プログラムを異常終了                 |
!> | SysdepArgGet    | コマンドライン引数を取得             |
!> | SysdepArgCount  | コマンドライン引数の数を取得         |
!> | SysdepEnvGet    | 環境変数を取得                       |
!>
!> @endja
 
module sysdep
  use, intrinsic :: iso_c_binding
  implicit none
  private
  public :: abortprogram
  public :: sysdepargget
  public :: sysdepargcount
  public :: sysdepenvget
 
  interface
    subroutine dc_f_abort() &
      ! bind(C, name="dc_c_abort")
      bind(C, name="abort")
      import
    end subroutine dc_f_abort
  end interface
 
contains
 
  !> -------------------------------------------------------------------------
  !> @en
  !> @brief Abort program execution
  !> @details
  !> Aborts the program, optionally displaying an error message to stderr.
  !> @param[in] message Optional error message to display before aborting
  !> @enden
  !>
  !> @ja
  !> @brief プログラムを異常終了させます
  !> @details
  !> プログラムを異常終了させます.
  !> オプションでエラーメッセージを標準エラー出力に表示します.
  !> @param[in] message 表示するエラーメッセージ (オプション)
  !> @endja
  !>
  subroutine abortprogram(message)
    use dc_types, only: stderr
    implicit none
    character(len=*), intent(in), optional :: message
    continue
    if (present(message)) write(stderr, *) trim(message)
    call dc_f_abort()
  end subroutine abortprogram
 
  !> -------------------------------------------------------------------------
  !> @en
  !> @brief Get number of command line arguments
  !> @details
  !> Returns the number of command line arguments passed to the program.
  !> @return Number of command line arguments
  !> @enden
  !>
  !> @ja
  !> @brief コマンドライン引数の数を取得します
  !> @details
  !> プログラムに渡されたコマンドライン引数の数を返します.
  !> @return コマンドライン引数の数
  !> @endja
  !>
  integer function sysdepargcount()
    implicit none
    sysdepargcount = command_argument_count()
  end function sysdepargcount
 
  !> -------------------------------------------------------------------------
  !> @en
  !> @brief Get command line argument
  !> @details
  !> Retrieves the command line argument at the specified index.
  !> Negative indices count from the end (e.g., -1 is the last argument).
  !> @param[in]  index Index of the argument to retrieve
  !> @param[out] val   Value of the argument
  !> @enden
  !>
  !> @ja
  !> @brief コマンドライン引数を取得します
  !> @details
  !> 指定されたインデックスのコマンドライン引数を取得します.
  !> 負のインデックスは末尾からカウントします (例: -1 は最後の引数).
  !> @param[in]  index 取得する引数のインデックス
  !> @param[out] val   引数の値
  !> @endja
  !>
  subroutine sysdepargget(index, val)
    implicit none
    integer,            intent(in)  :: index
    character(len = *), intent(out) :: val
    !
    integer:: idx
    integer:: argc
    continue
    argc = sysdepargcount()
    if (index < 0) then
      idx = argc + 1 + index
    else
      idx = index
    endif
    if (idx > argc) then
      val = ''
    else
      call get_command_argument(index, val)
    end if
  end subroutine sysdepargget
 
  !> -------------------------------------------------------------------------
  !> @en
  !> @brief Get environment variable
  !> @details
  !> Retrieves the value of the specified environment variable.
  !> @param[in]  env Name of the environment variable
  !> @param[out] str Value of the environment variable
  !> @enden
  !>
  !> @ja
  !> @brief 環境変数を取得します
  !> @details
  !> 指定された環境変数の値を取得します.
  !> @param[in]  env 環境変数の名前
  !> @param[out] str 環境変数の値
  !> @endja
  !>
  subroutine sysdepenvget(env, str)
    character(len = *), intent(in)  :: env
    character(len = *), intent(out) :: str
    call get_environment_variable(trim(adjustl(env)), str)
  end subroutine sysdepenvget
 
end module sysdep