gtool_historyauto_internal::hstvarsoutputcheck Interface Reference

Public Member Functions
subroutine	hstvarsoutputcheck (time, stime_index)

Detailed Description

Definition at line 336 of file gtool_historyauto_internal.f90.

Constructor & Destructor Documentation

hstvarsoutputcheck()

subroutine gtool_historyauto_internal::hstvarsoutputcheck::hstvarsoutputcheck	(	real(dp), intent(in)	time,
		integer, intent(out)	stime_index )

Check output timing for each variable.

It is investigated whether time is output timing for each variable, and the information is reflected to output_timing_vars, output_timing_avr_vars, create_timing_vars, close_timing_vars, renew_timing_vars. And index of array saved_time is returned to stime_index.

And if current time is timing of open/close of files, they are done in this subroutine.

Parameters

[in]	time	Current time.
[out]	stime_index	Index of saved_time array.

Definition at line 449 of file gtool_historyauto_internal.f90.

    use dc_trace, only: beginsub, endsub, dbgmessage
    use dc_error, only: storeerror, dc_noerr
    use gtool_history, only: historyinitialized, historyclose
    use dc_date_types, only: dc_difftime
    use dc_date, only: operator(==), operator(>), operator(<), &
      & operator(>=), operator(<=), operator(-), dcdifftimeputline, &
      & evalsec
    implicit none
    real(DP), intent(in):: time
                              ! 現在時刻. Current time
    integer, intent(out):: stime_index
 
    integer:: tstep
    integer:: stat, i, startnum, endnum
    character(STRING):: cause_c
    character(*), parameter:: subname = "HstVarsOutputCheck"
    real(DP), parameter:: time_eps = epsilon(1.0_dp)
  continue
    call beginsub(subname)
    stat = dc_noerr
    cause_c = ""
 
    ! 与えられた時刻がチェック済みかどうかを調べる
    ! Examine whether given time is already checked or not
    !
    timestepsearch: do
      do i = saved_tstep, checked_tstepnum
        if ( abs(saved_time(i) - time) <= &
          & time_eps * max(1.0_dp, abs(time), abs(saved_time(i))) ) then
          tstep = i
          exit timestepsearch
        end if
      end do
      do i = 1, saved_tstep - 1
        if ( abs(saved_time(i) - time) <= &
          & time_eps * max(1.0_dp, abs(time), abs(saved_time(i))) ) then
          tstep = i
          exit timestepsearch
        end if
      end do
 
      tstep = 0
      exit timestepsearch
    end do timestepsearch
 
    saved_tstep = tstep
 
    if ( saved_tstep /= 0 .and. checked_tstep_varnum == numvars ) then
      ! * output_timing_vars(:,saved_tstep) を使う.
      ! * saved_tstep を stime_index として返す.
 
      stime_index = saved_tstep
      call dbgmessage( 'saved_tstep=<%d> is already checked.', &
        & i =(/ saved_tstep /) )
      goto 999
    end if
 
    ! チェックする時間ステップと, 変数 ID の設定
    ! Configure checked time step, and variable ID
    !
    if ( saved_tstep /= 0 ) then
      startnum = checked_tstep_varnum + 1
      endnum   = numvars
 
      stime_index = saved_tstep
    else
      startnum = 1
      endnum   = numvars
 
      if ( save_tstepnum < 2 ) then
        checked_tstepnum = 1
        saved_time(checked_tstepnum) = time
 
        saved_tstep = checked_tstepnum
        stime_index = saved_tstep
 
      elseif ( .not. checked_tstepnum < save_tstepnum ) then
        create_timing_vars(:,1:checked_tstepnum-1) = create_timing_vars(:,2:checked_tstepnum)
        close_timing_vars(:,1:checked_tstepnum-1) = close_timing_vars(:,2:checked_tstepnum)
        renew_timing_vars(:,1:checked_tstepnum-1) = renew_timing_vars(:,2:checked_tstepnum)
        output_timing_vars(:,1:checked_tstepnum-1) = output_timing_vars(:,2:checked_tstepnum)
        output_timing_avr_vars(:,1:checked_tstepnum-1) = output_timing_avr_vars(:,2:checked_tstepnum)
 
        saved_time(1:checked_tstepnum-1) = saved_time(2:checked_tstepnum)
        saved_time(checked_tstepnum) = time
 
        saved_tstep = checked_tstepnum
        stime_index = saved_tstep
 
      else
        checked_tstepnum = checked_tstepnum + 1
        saved_time(checked_tstepnum) = time
 
        saved_tstep = checked_tstepnum
        stime_index = saved_tstep
      end if
    end if
 
    call dbgmessage( 'numvar=<%d:%d> in saved_tstep=<%d> will be checked from now.', &
      & i =(/ startnum, endnum, saved_tstep /) )
 
 
    ! それぞれのタイミングをチェックして各変数に格納
    !
    ! * ファイルオープン:      create_timing_vars
    ! * ファイルクローズ:      close_timing_vars
    ! * ファイルクローズ/作成: renew_timing_vars
    ! * データ出力:            output_timing_vars
    ! * データ平均化:          output_avr_timing_vars
 
    create_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    close_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    renew_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    output_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    output_timing_avr_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
 
    do i = startnum, endnum
 
      if ( .not. output_valid_vars(i) ) cycle
 
      if ( origin_time_vars(i) > time ) cycle
 
      if (             origin_time_vars(i) <= time &
        &  .and.       (      terminus_time_vars(i) < zero_time &
        &                .or. terminus_time_vars(i) >= time      ) &
        &  .and. .not. histaddvar_vars(i)            ) then
 
        create_timing_vars(i,checked_tstepnum) = .true.
 
        if ( newfile_inttime_vars(i) > zero_time ) then
          newfile_createtime_vars(i) = time
        end if
 
        output_timing_vars(i,checked_tstepnum) = .true.
        output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
        cycle
      end if
 
      if ( terminus_time_vars(i) > zero_time .and. terminus_time_vars(i) < time ) then
        close_timing_vars(i,checked_tstepnum) = .true.
        output_timing_vars(i,checked_tstepnum) = .false.
        output_timing_avr_vars(i,checked_tstepnum) = .false.
        cycle
      end if
 
      ! * newfile_inttime_vars だけでは, ぴったり一致しないとうまく行かない.
      !   * そこで...
      !     * 前回に出力した時刻を記憶しておく.
      !     * 前回の時刻と今回の時刻の差が newfile_inttime_vars
      !       よりも大きい場合には現ファイルを閉じ, 新ファイルを作成する.
 
      if ( newfile_inttime_vars(i) > zero_time ) then
        if ( time - newfile_createtime_vars(i) >= newfile_inttime_vars(i) ) then
          renew_timing_vars(i,checked_tstepnum) = .true.
 
          output_timing_vars(i,checked_tstepnum) = .true.
          output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
 
          cycle
        end if
      end if
 
      if ( time - prev_outtime_vars(i) >= interval_time_vars(i) ) then
        output_timing_vars(i,checked_tstepnum) = .true.
        output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
        cycle
      end if
 
      output_timing_vars(i,checked_tstepnum) = .false.
      output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
 
    end do
 
    checked_tstep_varnum = numvars
 
999 continue
    call storeerror(stat, subname, cause_c = cause_c)
    call endsub(subname)

References dc_trace::beginsub(), gtool_historyauto_internal::checked_tstep_varnum, gtool_historyauto_internal::checked_tstepnum, gtool_historyauto_internal::close_timing_vars, gtool_historyauto_internal::create_timing_vars, dc_trace::dbgmessage(), dc_error::dc_noerr, dcdifftimeputline(), dc_trace::endsub(), gtool_historyauto_internal::histaddvar_vars, historyclose(), gtool_historyauto_internal::interval_time_vars, gtool_historyauto_internal::newfile_createtime_vars, gtool_historyauto_internal::newfile_inttime_vars, gtool_historyauto_internal::numvars, gtool_historyauto_internal::origin_time_vars, gtool_historyauto_internal::output_timing_avr_vars, gtool_historyauto_internal::output_timing_vars, gtool_historyauto_internal::output_valid_vars, gtool_historyauto_internal::prev_outtime_vars, gtool_historyauto_internal::renew_timing_vars, gtool_historyauto_internal::save_tstepnum, gtool_historyauto_internal::saved_time, gtool_historyauto_internal::saved_tstep, dc_error::storeerror(), gtool_historyauto_internal::tavr_vars, gtool_historyauto_internal::terminus_time_vars, and gtool_historyauto_internal::zero_time.

Here is the call graph for this function:

---

The documentation for this interface was generated from the following file:

• /build/gtool5-1.0.0~rc5/debian/build-parallel/src/gtool/gtool_historyauto/gtool_historyauto_internal.f90