dc_url::urlsplit Interface Reference

Public Member Functions
subroutine	url_split_c (fullname, file, var, attr, iorange)

Detailed Description

Definition at line 77 of file dc_url.f90.

Member Function/Subroutine Documentation

url_split_c()

subroutine dc_url::urlsplit::url_split_c	(	character(len = *), intent(in)	fullname,
		character(len = *), intent(out), optional	file,
		character(len = *), intent(out), optional	var,
		character(len = *), intent(out), optional	attr,
		character(len = *), intent(out), optional	iorange )

Split variable URL to components

Splits the variable URL given in fullname into filename file, variable name var, attribute name attr, and I/O range specification iorange and returns them. Components that are not found are assigned empty strings.

Parameters

[in]	fullname	Variable URL
[out]	file	Filename (optional)
[out]	var	Variable name (optional)
[out]	attr	Attribute name (optional)
[out]	iorange	I/O range specification (optional)

Definition at line 403 of file dc_url.f90.

    use dc_types, only: string
    character(len = *), intent(in):: fullname
    character(len = *), intent(out), optional:: file, var, attr, iorange
    character(len = STRING):: varpart
    integer:: atmark, colon, comma
    character(len = *), parameter:: VARNAME_SET &
      = "0123456789eEdD+-=^,.:_" &
      // "ABCDEFGHIJKLMNOPQRSTUVWXYZ" &
      // "abcdefghijklmnopqrstuvwxyz"
  continue
    ! まず URL と変数属性指定 (? または @ 以降) を分離する。
    ! URL は @ を含みうるため、最後の @ 以降に対して変数属性
    ! として許されない文字（典型的には '/'）が含まれていたら
    ! 当該 @ は URL の一部とみなす。
    atmark = index(fullname, gt_question)
    if (atmark == 0) then
      atmark = index(fullname, gt_atmark, back=.true.)
      if (atmark /= 0) then
        if (verify(trim(fullname(atmark+1: )), varname_set) /= 0) then
          atmark = 0
        endif
      endif
    endif
    if (atmark == 0) then
      ! 変数属性指定はなかった。
      if (present(file)) file = fullname
      if (present(var)) var = ''
      if (present(attr)) attr = ''
      if (present(iorange)) iorange = ''
      return
    endif
    varpart = fullname(atmark+1: )
    ! 変数属性指定があった。
    if (present(file)) file = fullname(1: atmark - 1)
    ! 範囲指定を探索する。
    comma = index(varpart, gt_comma)
    if (comma /= 0) then
      ! 範囲指定がみつかった。
      if (present(var)) var = varpart(1: comma - 1)
      if (present(attr)) attr = ''
      if (present(iorange)) iorange = varpart(comma + 1: )
      return
    endif
    if (present(iorange)) iorange = ''
    ! 範囲指定がなかったので、属性名の検索をする。
    colon = index(varpart, gt_colon)
    if (colon == 0) then
      if (present(var)) var = varpart
      if (present(attr)) attr = ''
      varpart = ''
      return
    endif
    if (present(var)) var = varpart(1: colon - 1)
    if (present(attr)) attr = varpart(colon + 1: )
    varpart = ''

References dc_url::gt_atmark, dc_url::gt_colon, dc_url::gt_comma, dc_url::gt_question, and dc_types::string.

---

The documentation for this interface was generated from the following file:

• dc_utils/dc_url.f90