hstnmlinforesetdefault.f90

Go to the documentation of this file.

!> @file hstnmlinforesetdefault.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Stored data is deleted without default settings
!> @enden
!>
!> @ja
!> @brief デフォルト値を残し, 登録したデータを削除
!> @endja
 
  !> @en
  !> @brief Reset to default settings
  !>
  !> Stored data is deleted without default settings.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief デフォルト設定のみに戻す
  !>
  !> デフォルト値を残し, 登録したデータを削除します.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[inout] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[out] err 例外処理用フラグ. Exception handling flag.
  subroutine hstnmlinforesetdefault( gthstnml, err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo
    use gtool_history_nmlinfo_generic, only: hstnmlinfodelete, hstnmlinfogetnames
    use dc_trace, only: beginsub, endsub
    use dc_types, only: string, token
    use dc_error, only: storeerror, dc_noerr, dc_enotinit, hst_enotindefine
    implicit none
    type(gthst_nmlinfo), intent(inout):: gthstnml
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    character(TOKEN), pointer:: varnames_array(:) =>null()
    integer:: i, vnmax
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoResetDefault'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) then
      stat = dc_enotinit
      cause_c = 'GTHST_NMLINFO'
      goto 999
    end if
 
    if ( .not. gthstnml % define_mode ) then
      stat = hst_enotindefine
      cause_c = 'ResetDefault'
      goto 999
    end if
 
    !-----------------------------------------------------------------
    !  変数名リストの取得
    !  Get varnames list
    !-----------------------------------------------------------------
    call hstnmlinfogetnames( gthstnml, & ! (in)
      & varnames_array )                 ! (out)
    vnmax = size( varnames_array )
 
    do i = 1, vnmax
      call hstnmlinfodelete( &
        & gthstnml = gthstnml, &     ! (inout)
        & name = varnames_array(i) ) ! (in)
    end do
 
    deallocate( varnames_array )
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinforesetdefault