hstnmlinfogetnames.f90

Go to the documentation of this file.

!> @file hstnmlinfogetnames.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Return list of variables as character array pointer
!> @enden
!>
!> @ja
!> @brief 変数リストを文字列型配列ポインタとして取得
!> @endja
 
  !> @en
  !> @brief Return list of registered variable identifiers as character array pointer
  !>
  !> List of variables registered in @p gthstnml is returned to
  !> character array pointer.
  !> Nullify @p varnames_ary before it is given to this subroutine.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief 登録されている変数名リストを文字型配列ポインタとして返す
  !>
  !> @p gthstnml に設定されている変数リストを文字型配列ポインタに
  !> 返します. @p varnames_ary は空状態にして与えてください.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[in] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[out] varnames_ary 変数名の配列ポインタ.
  !>                          Character array pointer of variable names.
  !> @param[out] err 例外処理用フラグ. Exception handling flag.
  subroutine hstnmlinfogetnames( gthstnml, varnames_ary, err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listnext
    use dc_trace, only: beginsub, endsub
    use dc_types, only: string, token
    use dc_error, only: storeerror, dc_noerr, dc_enotinit
    use netcdf, only: nf90_max_vars
    implicit none
    type(gthst_nmlinfo), intent(in):: gthstnml
    character(TOKEN), pointer:: varnames_ary(:) ! (out)
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ.
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します.
                              ! 引数 *err* が与えられる場合,
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます.
                              !
                              ! Exception handling flag.
                              ! By default, when error occur in
                              ! this procedure, the program aborts.
                              ! If this *err* argument is given,
                              ! .true. is substituted to *err* and
                              ! the program does not abort.
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    integer:: varnums, ary_size
    character(TOKEN), allocatable:: varnames_ary_tmp1(:), varnames_ary_tmp2(:)
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoNames'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    varnums = 0
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) then
      stat = dc_enotinit
      cause_c = 'GTHST_NMLINFO'
      goto 999
    end if
 
    !-----------------------------------------------------------------
    !  割り付け
    !  Allocate
    !-----------------------------------------------------------------
    if ( associated(varnames_ary) ) deallocate(varnames_ary)
    allocate( varnames_ary_tmp1(1:nf90_max_vars) )
 
    !-----------------------------------------------------------------
    !  情報の取り出し
    !  Fetch information
    !-----------------------------------------------------------------
    hptr => gthstnml % gthstnml_list
    do while ( associated( hptr % next ) )
      call listnext( gthstnml_list = hptr ) ! (inout)
      varnums = varnums + 1
      ary_size = size( varnames_ary_tmp1 )
      if ( varnums > ary_size ) then
        allocate( varnames_ary_tmp2(1:ary_size) )
        varnames_ary_tmp2(1:ary_size) = varnames_ary_tmp1(1:ary_size)
        deallocate( varnames_ary_tmp1 )
        allocate( varnames_ary_tmp1(1:varnums*2) )
        varnames_ary_tmp1(1:ary_size) = varnames_ary_tmp2(1:ary_size)
        deallocate( varnames_ary_tmp2 )
      end if
 
      varnames_ary_tmp1(varnums) = adjustl( hptr % name )
    end do
 
    if ( varnums > 0 ) then
      allocate( varnames_ary(1:varnums) )
      varnames_ary(1:varnums) = varnames_ary_tmp1(1:varnums)
    else
      allocate( varnames_ary(1:1) )
      varnames_ary = ''
    end if
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    nullify( hptr )
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfogetnames