historyvarinfoinquire.f90

Go to the documentation of this file.

!> @file historyvarinfoinquire.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Inquire a GT_HISTORY_VARINFO variable
!> @enden
!>
!> @ja
!> @brief GT_HISTORY_VARINFO 型変数への問い合わせ
!> @endja
 
!>
!> @en
!> @brief Inquire a GT_HISTORY_VARINFO variable
!>
!> Retrieves each piece of information from a GT_HISTORY_VARINFO variable.
!> dims is a pointer array; pass it in a null state.
!> @param[in] varinfo GT_HISTORY_VARINFO variable
!> @param[out] name Variable name (optional)
!> @param[out] dims Dependent dimensions, pointer (optional)
!> @param[out] longname Descriptive name of the variable (optional)
!> @param[out] units Units of the variable (optional)
!> @param[out] xtype Type of the variable (optional)
!> @param[out] time_average Time average flag (optional)
!> @param[out] average Time average flag for backward compatibility (optional)
!> @param[out] err Exception handling flag (optional)
!> @enden
!>
!> @ja
!> @brief GT_HISTORY_VARINFO 型変数への問い合わせ
!>
!> GT_HISTORY_VARINFO 型の変数内の各情報を参照します。
!> dims はポインタ配列です。空状態にして与えてください。
!> @param[in] varinfo GT_HISTORY_VARINFO 型変数
!> @param[out] name 変数名 (optional)
!> @param[out] dims 依存する次元, ポインタ (optional)
!> @param[out] longname 変数の記述的名称 (optional)
!> @param[out] units 変数の単位 (optional)
!> @param[out] xtype 変数の型 (optional)
!> @param[out] time_average 時間平均 (optional)
!> @param[out] average 時間平均 (後方互換用) (optional)
!> @param[out] err 例外処理用フラグ (optional)
!> @endja
!>
  subroutine historyvarinfoinquire1( varinfo, & ! (in)
    & name, dims, longname, units, xtype, &     ! (out) optional
    & time_average, average, err &              ! (out) optional
    & )
    use dc_types, only: string
    use dc_trace, only: beginsub, endsub
    use dc_error, only: storeerror, dc_noerr, dc_enotinit
    use gtool_history_types, only: gt_history_varinfo
    implicit none
    type(gt_history_varinfo),intent(in) :: varinfo
    character(*), intent(out), optional:: name     ! 変数名
    character(*), pointer,     optional:: dims(:)  !(out) 依存する次元
    character(*), intent(out), optional:: longname ! 変数の記述的名称
    character(*), intent(out), optional:: units    ! 変数の単位
    character(*), intent(out), optional:: xtype    ! 変数の型
    logical, intent(out), optional:: time_average  ! 時間平均
    logical, intent(out), optional:: average       ! 時間平均 (後方互換用)
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    ! Internal Work
    integer:: i, numdims, stat
    character(STRING):: cause_c
    character(*), parameter:: subname = "HistoryVarinfoInquire1"
  continue
    call beginsub(subname)
    stat = dc_noerr
    cause_c = ''
 
    if ( .not. varinfo % initialized ) then
      stat = dc_enotinit
      cause_c = 'GT_HISTORY_VARINFO'
      goto 999
    end if
    if (present(name)) name = varinfo % name
    if (present(dims)) then
      numdims = size(varinfo % dims)
      allocate(dims(numdims))
      do i = 1, numdims
        dims(i) = varinfo % dims(i)
      end do
    end if
    if ( present(longname) ) longname = varinfo % longname
    if ( present(units)    ) units    = varinfo % units
    if ( present(xtype)    ) xtype    = varinfo % xtype
    if ( present(time_average)  ) time_average  = varinfo % time_average
    if ( present(average)  )           average  = varinfo % time_average
 
999 continue
    call storeerror(stat, subname, err, cause_c=cause_c)
    call endsub(subname)
  end subroutine historyvarinfoinquire1
 
  !> @en
  !> @brief Inquire a GT_HISTORY_VARINFO variable (generic interface)
  !>
  !> Usage is same as HistoryVarinfoInquire.
  !> @enden
  !> @ja
  !> @brief GT_HISTORY_VARINFO 型変数への問い合わせ (総称インターフェース)
  !>
  !> 使用方法は HistoryVarinfoInquire と同様です。
  !> @endja
  subroutine historyvarinfoinquire2( varinfo, & ! (in)
    & name, dims, longname, units, xtype, &     ! (out) optional
    & time_average, average, err &              ! (out) optional
    & )
    use gtool_history_types, only: gt_history_varinfo
    use gtool_history_generic, only: historyvarinfoinquire
    use dc_trace, only: beginsub, endsub
    implicit none
    type(gt_history_varinfo),intent(in) :: varinfo
    character(*), intent(out), optional:: name     ! 変数名
    character(*), pointer,     optional:: dims(:)  !(out) 依存する次元
    character(*), intent(out), optional:: longname ! 変数の記述的名称
    character(*), intent(out), optional:: units    ! 変数の単位
    character(*), intent(out), optional:: xtype    ! 変数の型
    logical, intent(out), optional:: time_average  ! 時間平均
    logical, intent(out), optional:: average       ! 時間平均 (後方互換用)
    logical, intent(out), optional:: err
    character(*), parameter:: subname = "HistoryVarinfoInquire2"
  continue
    call beginsub(subname)
    call historyvarinfoinquire( varinfo, &
      & name, dims, longname, units, xtype, &
      & time_average, average, err )
    call endsub(subname)
  end subroutine historyvarinfoinquire2