historyinquire.f90

Go to the documentation of this file.

!> @file historyinquire.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2004-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Inquire for a GT_HISTORY variable
!> @enden
!>
!> @ja
!> @brief GT_HISTORY 型変数への問い合わせ
!> @endja
 
!>
!> @en
!> @brief Inquire a GT_HISTORY variable
!>
!> Retrieves values set by HistoryCreate, HistoryAddVariable, etc.
!> For file, title, source, institution, origin, interval,
!> conventions, gt_version, dims, dimsizes, longnames, units,
!> xtypes, see HistoryCreate.
!>
!> For title, source, institution, origin, interval, conventions,
!> gt_version, "unknown" is returned if values are not available.
!>
!> dims, dimsizes, longnames, units, xtypes return values via
!> pointer; pass null pointers.
!>
!> axes and varinfo return axis and variable information respectively.
!>
!> HistoryInquire is a generic name for two subroutines.
!>
!> @param[in]  history      History handle
!> @param[out] err          Error flag (optional)
!> @param[out] file         Output file name (optional)
!> @param[out] title        Title (optional)
!> @param[out] source       Source (optional)
!> @param[out] institution  Institution (optional)
!> @param[out] origin       Origin time (optional)
!> @param[out] interval     Output interval (optional)
!> @param[out] newest       Newest time (optional)
!> @param[out] oldest       Oldest time (optional)
!> @param[out] conventions  Conventions (optional)
!> @param[out] gt_version   gt_version (optional)
!> @param[out] dims         Dimension names (pointer, optional)
!> @param[out] dimsizes     Dimension sizes (pointer, optional)
!> @param[out] longnames    Long names (pointer, optional)
!> @param[out] units        Units (pointer, optional)
!> @param[out] xtypes       Types (pointer, optional)
!> @param[out] axes         Axis information (pointer, optional)
!> @param[out] varinfo      Variable information (pointer, optional)
!> @enden
!>
!> @ja
!> @brief GT_HISTORY 型変数への問い合わせ
!>
!> HistoryCreate や HistoryAddVariable などで設定した値の
!> 参照を行います。
!>
!> file, title, source, institution, origin, interval,
!> conventions, gt_version, dims, dimsizes, longnames, units,
!> xtypes に関しては HistoryCreate を参照してください。
!>
!> title, source, institution, origin, interval, conventions, gt_version
!> に関しては、値が得られなかった場合は "unknown" が返ります。
!>
!> dims, dimsizes, longnames, units, xtypes に関してはポインタに
!> 値を返すため、必ずポインタを空状態にしてから与えてください。
!>
!> axes と varinfo にはそれぞれ座標軸情報と変数情報を返します。
!>
!> HistoryInquire は 2 つのサブルーチンの総称名です。
!> @param[in]  history      ヒストリーハンドル
!> @param[out] err          エラーフラグ (省略可能)
!> @param[out] file         出力ファイル名 (省略可能)
!> @param[out] title        タイトル (省略可能)
!> @param[out] source       ソース (省略可能)
!> @param[out] institution  組織 (省略可能)
!> @param[out] origin       開始時間 (省略可能)
!> @param[out] interval     出力時間間隔 (省略可能)
!> @param[out] newest       最新の時刻 (省略可能)
!> @param[out] oldest       最初の時刻 (省略可能)
!> @param[out] conventions  規約 (省略可能)
!> @param[out] gt_version   gtバージョン (省略可能)
!> @param[out] dims         次元名 (ポインタ, 省略可能)
!> @param[out] dimsizes     次元サイズ (ポインタ, 省略可能)
!> @param[out] longnames    長い名前 (ポインタ, 省略可能)
!> @param[out] units        単位 (ポインタ, 省略可能)
!> @param[out] xtypes       型 (ポインタ, 省略可能)
!> @param[out] axes         座標軸情報 (ポインタ, 省略可能)
!> @param[out] varinfo      変数情報 (ポインタ, 省略可能)
!> @endja
!>
  subroutine historyinquire1(history, err, file, title, source, &
    & dims, dimsizes, longnames, units, xtypes, &
    & institution, origin, interval, newest, oldest, &
    & conventions, gt_version, &
    & axes, varinfo )
    !
    use gtool_history_types, only: gt_history, gt_history_axis, gt_history_varinfo
    use gtdata_generic, only: inquire, get_attr, open, close
    use gtdata_types, only: gt_variable
    use dc_url, only: urlsplit
    use dc_error, only: storeerror, dc_noerr, gt_ebadhistory, nf90_enotvar
    use dc_trace, only: beginsub, endsub
    use dc_types, only: string, token
    implicit none
    type(gt_history), intent(in):: history
    logical, intent(out), optional :: err
    character(*), intent(out), optional:: file, title, source, institution
    real,intent(out), optional:: origin, interval
    real,intent(out), optional:: newest ! 最新の時刻
    real,intent(out), optional:: oldest ! 最初の時刻
    character(*), intent(out), optional:: conventions, gt_version
    character(*), pointer, optional:: dims(:) ! (out)
    integer,pointer, optional:: dimsizes(:) ! (out)
    character(*), pointer, optional:: longnames(:) ! (out)
    character(*), pointer, optional:: units(:) ! (out)
    character(*), pointer, optional:: xtypes(:) ! (out)
    type(gt_history_axis), pointer, optional :: axes(:) ! (out)
    type(gt_history_varinfo), pointer, optional :: varinfo(:) ! (out)
 
    ! Internal Work
    character(STRING)      :: url, cause_c
    character(TOKEN)       :: unknown_mes = 'unknown'
    integer          :: i, j, numdims, numvars, alldims, stat
    logical                :: growable
    type(gt_variable)      :: dimvar
    character(*), parameter:: subname = "HistoryInquire1"
  continue
    call beginsub(subname)
    stat = dc_noerr
    cause_c =  ''
    if (.not. associated(history % dimvars) .or. &
      & size(history % dimvars) < 1) then
      stat = gt_ebadhistory
      goto 999
    end if
 
    if (present(file)) then
      call inquire(history % dimvars(1), url=url)
      call urlsplit(fullname=url, file=file)
    end if
    if (present(title)) then
      call get_attr(history % dimvars(1), '+title', title, trim(unknown_mes))
    end if
    if (present(source)) then
      call get_attr(history % dimvars(1), '+source', source, trim(unknown_mes))
    end if
    if (present(institution)) then
      call get_attr(history % dimvars(1), '+institution', institution, trim(unknown_mes))
    end if
 
    if (present(origin)) then
      origin = real(history % origin, kind=kind(origin))
!      origin = EvalByUnit( history % origin, '', history % unlimited_units_symbol )
    end if
    if (present(interval)) then
      interval = real(history % interval, kind=kind(interval))
!      interval = EvalByUnit( history % interval, '', history % unlimited_units_symbol )
    end if
    if (present(newest)) then
      newest = real(history % newest, kind=kind(newest))
!      newest = EvalByUnit( history % newest, '', history % unlimited_units_symbol )
    end if
    if (present(oldest)) then
      oldest = real(history % oldest, kind=kind(oldest))
!      oldest = EvalByUnit( history % oldest, '', history % unlimited_units_symbol )
    end if
    if (present(conventions)) then
      call get_attr(history % dimvars(1), '+Conventions', conventions, trim(unknown_mes))
    end if
    if (present(gt_version)) then
      call get_attr(history % dimvars(1), '+gt_version', gt_version, trim(unknown_mes))
    end if
    if (present(dims)) then
      numdims = size(history % dimvars)
      allocate(dims(numdims))
      do i = 1, numdims
        call inquire(history % dimvars(i), name=dims(i))
      end do
    end if
    if (present(dimsizes)) then
      numdims = size(history % dimvars)
      allocate(dimsizes(numdims))
      do i = 1, numdims
        call inquire(history % dimvars(i), size=dimsizes(i), growable=growable)
        if (growable) dimsizes(i) = 0
      end do
    end if
    if (present(longnames)) then
      numdims = size(history % dimvars)
      allocate(longnames(numdims))
      do i = 1, numdims
        call get_attr(history % dimvars(i), 'long_name', &
          & longnames(i), 'unknown')
      end do
    end if
    if (present(units)) then
      numdims = size(history % dimvars)
      allocate(units(numdims))
      do i = 1, numdims
        call get_attr(history % dimvars(i), 'units', &
          & units(i), 'unknown')
      end do
    end if
    if (present(xtypes)) then
      numdims = size(history % dimvars)
      allocate(xtypes(numdims))
      do i = 1, numdims
        call inquire(history % dimvars(i), xtype=xtypes(i))
      end do
    end if
    if (present(axes)) then
      numvars = size(history % dimvars)
      allocate(axes(numvars))
      do i = 1, numvars
        call inquire(history % dimvars(i), &
          & allcount=axes(i) % length, &
          & xtype=axes(i) % xtype, name=axes(i) % name)
        call get_attr(history % dimvars(i), 'long_name', &
          & axes(i) % longname, 'unknown')
        call get_attr(history % dimvars(i), 'units', &
          & axes(i) % units, 'unknown')
 
        ! 属性 GT_HISTORY_ATTR はまだ取得できない
        !
        ! するためには, 属性名に対して様々な型が存在しうると
        ! 考えられるため, get_attr (gtdata_generic および gtdata_netcdf_generic)
        ! に err 属性を装備させ, 取得できない際にエラーを
        ! 返してもらわなければならないだろう.
 
      end do
    end if
 
    if (present(varinfo)) then
       if (.not. associated(history % vars) ) then
        stat = nf90_enotvar
        goto 999
      end if
      if ( size(history % vars) < 1) then
        stat = nf90_enotvar
        goto 999
      end if
      numvars = size(history % vars)
      allocate(varinfo(numvars))
      do i = 1, numvars
        call inquire(history % vars(i), alldims=alldims, &
          & xtype=varinfo(i) % xtype, name=varinfo(i) % name)
        call get_attr(history % vars(i), 'long_name', &
          & varinfo(i) % longname, 'unknown')
        call get_attr(history % vars(i), 'units', &
          & varinfo(i) % units, 'unknown')
 
        ! 属性 GT_HISTORY_ATTR はまだ取得できない
        !
        ! するためには, 属性名に対して様々な型が存在しうると
        ! 考えられるため, get_attr (gtdata_generic および gtdata_netcdf_generic)
        ! に err 属性を装備させ, 取得できない際にエラーを
        ! 返してもらわなければならないだろう.
 
        allocate(varinfo(i) % dims(alldims))
        do j = 1, alldims
          call open(var=dimvar, source_var=history % vars(i), &
            & dimord=j, count_compact=.true.)
          call inquire(dimvar, name=varinfo(i) % dims(j))
          call close(dimvar)
        end do
 
        varinfo(i) % initialized = .true.
 
      end do
    end if
999 continue
    call storeerror(stat, subname, err, cause_c=cause_c)
    call endsub(subname)
  end subroutine historyinquire1
 
  !-------------------------------------------------------------------
 
!> @en
  !> @brief Inquire a GT_HISTORY variable (character interface)
  !>
  !> Use this subroutine for inquiries when history was not
  !> specified in HistoryCreate. Pass the string "default" to history.
  !> @enden
  !> @ja
  !> @brief GT_HISTORY 型変数への問い合わせ (文字列インターフェース)
  !>
  !> HistoryCreate で history を指定しなかった場合はこちらの
  !> サブルーチンで問い合わせを行います。
  !> history には必ず "default" という文字列を与えてください。
  !> @endja
  subroutine historyinquire2(history, err, file, title, source, &
    & dims, dimsizes, longnames, units, xtypes, &
    & institution, origin, interval, newest, oldest, &
    & conventions, gt_version, &
    & axes, varinfo )
    use gtool_history_types, only: gt_history, gt_history_axis, gt_history_varinfo
    use gtool_history_internal, only: default
    use gtool_history_generic, only: historyinquire
    use dc_error, only: storeerror, dc_noerr, nf90_einval
    use dc_trace, only: beginsub, endsub
    use dc_types, only: string
    implicit none
    character(*), intent(in):: history
    logical, intent(out), optional :: err
    character(*), intent(out), optional:: file, title, source, institution
    real,intent(out), optional:: origin, interval, newest, oldest
    character(*), intent(out), optional:: conventions, gt_version
    character(*), pointer, optional:: dims(:) ! (out)
    integer,pointer, optional:: dimsizes(:) ! (out)
    character(*), pointer, optional:: longnames(:) ! (out)
    character(*), pointer, optional:: units(:) ! (out)
    character(*), pointer, optional:: xtypes(:) ! (out)
    type(gt_history_axis), pointer, optional :: axes(:) ! (out)
    type(gt_history_varinfo), pointer, optional :: varinfo(:) ! (out)
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = "HistoryInquire2"
  continue
    call beginsub(subname, "history=%c", c1=trim(history))
    stat = dc_noerr
    cause_c = ''
    if (trim(history) /= 'default') then
      stat = nf90_einval
      cause_c = 'history="' // trim(history) // '"'
      goto 999
    end if
    call historyinquire(default, err, file, title, source, &
      & dims, dimsizes, longnames, units, xtypes, &
      & institution, origin, interval, newest, oldest, &
      & conventions, gt_version, &
      & axes, varinfo )
999 continue
    call storeerror(stat, subname, cause_c=cause_c)
    call endsub(subname)
  end subroutine historyinquire2
 
  !-------------------------------------------------------------------
 
!> @en
  !> @brief Inquire a GT_HISTORY variable (generic interface)
  !>
  !> Usage is same as HistoryInquire.
  !> @enden
  !> @ja
  !> @brief GT_HISTORY 型変数への問い合わせ (総称インターフェース)
  !>
  !> 使用方法は HistoryInquire と同様です。
  !> @endja
  subroutine historyinquire3(history, err, file, title, source, &
    & dims, dimsizes, longnames, units, xtypes, &
    & institution, origin, interval, newest, oldest, &
    & conventions, gt_version, &
    & axes, varinfo )
    use gtool_history_types, only: gt_history, gt_history_axis, gt_history_varinfo
    use gtool_history_generic, only: historyinquire
    use dc_trace, only: beginsub, endsub
    implicit none
    type(gt_history), intent(in):: history
    logical, intent(out), optional :: err
    character(*), intent(out), optional:: file, title, source, institution
    real,intent(out), optional:: origin, interval
    real,intent(out), optional:: newest ! 最新の時刻
    real,intent(out), optional:: oldest ! 最初の時刻
    character(*), intent(out), optional:: conventions, gt_version
    character(*), pointer, optional:: dims(:) ! (out)
    integer,pointer, optional:: dimsizes(:) ! (out)
    character(*), pointer, optional:: longnames(:) ! (out)
    character(*), pointer, optional:: units(:) ! (out)
    character(*), pointer, optional:: xtypes(:) ! (out)
    type(gt_history_axis), pointer, optional :: axes(:) ! (out)
    type(gt_history_varinfo), pointer, optional :: varinfo(:) ! (out)
 
    character(*), parameter:: subname = "HistoryInquire3"
  continue
    call beginsub(subname)
    call historyinquire(history, err, file, title, source, &
      & dims, dimsizes, longnames, units, xtypes, &
      & institution, origin, interval, newest, oldest, &
      & conventions, gt_version, &
      & axes, varinfo )
    call endsub(subname)
  end subroutine historyinquire3
 
  !-------------------------------------------------------------------
 
!> @en
  !> @brief Inquire a GT_HISTORY variable (generic interface)
  !>
  !> Usage is same as HistoryInquire.
  !> @enden
  !> @ja
  !> @brief GT_HISTORY 型変数への問い合わせ (総称インターフェース)
  !>
  !> 使用方法は HistoryInquire と同様です。
  !> @endja
  subroutine historyinquire4(history, err, file, title, source, &
    & dims, dimsizes, longnames, units, xtypes, &
    & institution, origin, interval, newest, oldest, &
    & conventions, gt_version, &
    & axes, varinfo )
    use gtool_history_types, only: gt_history, gt_history_axis, gt_history_varinfo
    use gtool_history_generic, only: historyinquire
    use dc_trace, only: beginsub, endsub
    implicit none
    character(*), intent(in):: history
    logical, intent(out), optional :: err
    character(*), intent(out), optional:: file, title, source, institution
    real,intent(out), optional:: origin, interval, newest, oldest
    character(*), intent(out), optional:: conventions, gt_version
    character(*), pointer, optional:: dims(:) ! (out)
    integer,pointer, optional:: dimsizes(:) ! (out)
    character(*), pointer, optional:: longnames(:) ! (out)
    character(*), pointer, optional:: units(:) ! (out)
    character(*), pointer, optional:: xtypes(:) ! (out)
    type(gt_history_axis), pointer, optional :: axes(:) ! (out)
    type(gt_history_varinfo), pointer, optional :: varinfo(:) ! (out)
    character(*), parameter:: subname = "HistoryInquire4"
  continue
    call beginsub(subname)
    call historyinquire(history, err, file, title, source, &
      & dims, dimsizes, longnames, units, xtypes, &
      & institution, origin, interval, newest, oldest, &
      & conventions, gt_version, &
      & axes, varinfo )
    call endsub(subname)
  end subroutine historyinquire4