historyautochkoutput.f90

Go to the documentation of this file.

!> @file historyautochkoutput.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2010-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Check output setting of a variable
!> @enden
!>
!> @ja
!> @brief 変数の出力設定の確認手続
!> @endja
 
  !> @en
  !> @brief Check output setting of a variable
  !>
  !> If output setting of @p varname is valid, .true. is returned.
  !> If output setting of @p varname is invalid, .false. is returned.
  !>
  !> If initialization with HistoryAutoCreate is not done yet, .false. is returned.
  !> If @p varname is invalid, .false. is returned.
  !> @enden
  !>
  !> @ja
  !> @brief 変数の出力設定の確認
  !>
  !> @p varname に指定された変数名が出力されるよう設定されている
  !> 場合には .true. が, 出力されないよう設定されている場合は
  !> .false. が返ります.
  !>
  !> HistoryAutoCreate による初期設定がなされていない場合や,
  !> @p varname に指定された変数名が HistoryAutoAddVariable によって
  !> 登録されていない場合, 返り値に .false. が返ります.
  !> @endja
  !>
  !> @param[in] varname 変数の名前. Variable name.
  !> @return 出力設定が有効であれば .true.
  function historyautochkoutput( varname ) result(result)
    use gtool_historyauto_internal, only: initialized, numvars, &
      & varname_vars, output_valid_vars
 
    implicit none
    logical:: result
    character(*), intent(in):: varname
                              ! 変数の名前. 
                              ! Variable name
 
    integer:: i, vnum
    integer, save:: svnum = 1
  continue
    ! 初期設定チェック
    ! Check initialization
    !
    if ( .not. initialized ) then
      result = .false.
      goto 999
    end if
 
    ! 変数 ID のサーチ
    ! Search variable ID
    !
    varsearch: do
      do i = svnum, numvars
        if ( trim( varname_vars(i) ) == trim(varname) ) then
          vnum = i
          exit varsearch
        end if
      end do
      do i = 1, svnum - 1
        if ( trim( varname_vars(i) ) == trim(varname) ) then
          vnum = i
          exit varsearch
        end if
      end do
 
      result = .false.
      goto 999
    end do varsearch
 
    svnum = vnum
 
    ! 出力設定の確認
    ! Check output setting
    !
    result = output_valid_vars( vnum )
 
999 continue
  end function historyautochkoutput
 
 
 
  !> @en
  !> @brief Check output timing of a variable
  !>
  !> If @p varname is output on @p time, .true. is returned.
  !>
  !> Please use this function as follows.
  !>
  !>     if ( HistoryAutoChkOutputTiming( time, var ) ) then
  !>       <some operation ...>
  !>     end if
  !>
  !>     call HistoryAutoPut( time, var, data )
  !>
  !> Following usage does not return correct values.
  !>
  !>     do i = 1, 10
  !>       write(*,*) HistoryAutoChkOutputTiming( i * timestep, var )
  !>     end do
  !>
  !> If initialization with HistoryAutoCreate is not done yet, .false. is returned.
  !> If @p varname is invalid, .false. is returned.
  !> @enden
  !>
  !> @ja
  !> @brief 変数の出力タイミングの確認
  !>
  !> @p varname に指定された変数名が、@p time のタイミングで出力されるよう
  !> 設定されている場合には .true. が, 出力されないよう設定されている場合は
  !> .false. が返ります.
  !>
  !> なお, gtool_historyauto は時間ステップ可変に対応しているため,
  !> @p time のタイミングで出力されるかどうかについては,
  !> その前回に出力された時間に依存します. 従って, とある時間の
  !> 出力設定の確認は下記のように HistoryAutoPut の前で使用して下さい.
  !>
  !>     if ( HistoryAutoChkOutputTiming( time, var ) ) then
  !>       <some operation ...>
  !>     end if
  !>
  !>     call HistoryAutoPut( time, var, data )
  !>
  !> 以下のように使用した場合には, 期待するような返り値が
  !> 得られないことにご留意下さい.
  !>
  !>     do i = 1, 10
  !>       write(*,*) HistoryAutoChkOutputTiming( i * timestep, var )
  !>     end do
  !>
  !> HistoryAutoCreate による初期設定がなされていない場合や,
  !> @p varname に指定された変数名が HistoryAutoAddVariable によって
  !> 登録されていない場合, 返り値に .false. が返ります.
  !> @endja
  !>
  !> @param[in] time データの時刻. Time of data.
  !> @param[in] varname 変数の名前. Variable name.
  !> @return 出力タイミングであれば .true.
  function historyautochkoutputtiming( time, varname ) result(result)
    use gtool_historyauto_internal, only: initialized, numvars, &
      & varname_vars, output_valid_vars, origin_time_vars, histaddvar_vars, &
      & newfile_inttime_vars, newfile_createtime_vars, prev_outtime_vars, &
      & interval_time_vars, terminus_time_vars
    use dc_types, only: dp
 
    implicit none
    logical:: result
    real(dp), intent(in):: time
                              ! データの時刻. 
                              ! Time of data
    character(*), intent(in):: varname
                              ! 変数の名前. 
                              ! Variable name
 
    real(dp), parameter:: zero_time = 0.0_dp
    integer:: i, vnum
    integer, save:: svnum = 1
  continue
 
    ! 初期設定チェック
    ! Check initialization
    !
    if ( .not. initialized ) then
      result = .false.
      goto 999
    end if
 
    ! 変数 ID のサーチ
    ! Search variable ID
    !
    varsearch: do
      do i = svnum, numvars
        if ( trim( varname_vars(i) ) == trim(varname) ) then
          vnum = i
          exit varsearch
        end if
      end do
      do i = 1, svnum - 1
        if ( trim( varname_vars(i) ) == trim(varname) ) then
          vnum = i
          exit varsearch
        end if
      end do
 
      result = .false.
      goto 999
    end do varsearch
 
    svnum = vnum
 
    ! 出力設定の確認
    ! Check output setting
    !
    result = output_valid_vars( vnum )
 
    if ( .not. result ) goto 999
 
    if ( origin_time_vars(vnum) > time ) then
      result = .false. 
      goto 999
    end if
 
    if (             origin_time_vars(vnum) <= time &
      &  .and.       (      terminus_time_vars(vnum) < zero_time &
      &                .or. terminus_time_vars(vnum) >= time      ) &
      &  .and. .not. histaddvar_vars(vnum)            ) then
 
      result = .true.
      goto 999
    end if
 
    if ( terminus_time_vars(vnum) > zero_time .and. terminus_time_vars(vnum) < time ) then
      result = .false.
      goto 999
    end if
 
    if ( newfile_inttime_vars(vnum) > zero_time ) then
      if ( time - newfile_createtime_vars(vnum) >= newfile_inttime_vars(vnum) ) then
        result = .true.
        goto 999
      end if
    end if
 
    if ( time - prev_outtime_vars(vnum) >= interval_time_vars(vnum) ) then
      result = .true.
      goto 999
    end if
 
    result = .false.
 
999 continue
  end function historyautochkoutputtiming