gtvargetslice.f90

Go to the documentation of this file.

!> @file gtvargetslice.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Get variable I/O range restriction information
!>
!> This subroutine is provided as gtdata_generic#Get_Slice
!> through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 変数入出力範囲限定情報を取得
!>
!> このサブルーチンは gtdata_generic から gtdata_generic#Get_Slice
!> として提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Get I/O range information for specified dimension
!>
!> Gets I/O range information set by Slice for dimension dimord
!> of variable var. See Slice for start, count, stride.
!>
!> If count_compact is set to .true., queries including degenerate dimensions.
!>
!> Get_Slice is a generic name for 2 subroutines; there is also
!> a method to bulk get information for all dimensions.
!> @param[in]  var           Variable handle
!> @param[in]  dimord        Dimension order number
!> @param[out] start         Start index (optional)
!> @param[out] count         Count (optional)
!> @param[out] stride        Stride (optional)
!> @param[in]  count_compact Include degenerate dimensions (optional)
!> @enden
!>
!> @ja
!> @brief 指定次元の入出力範囲情報を取得
!>
!> 変数 var の dimord 番目の次元に関して、
!> Slice によって設定された入出力範囲の情報を取得します。
!> start, count, stride に関しては Slice を参照してください。
!>
!> count_compact に .true. を指定すると、縮退された次元も含んで問い合わせを行います。
!>
!> Get_Slice は 2 つのサブルーチンの総称名であり、
!> 他にも変数の依存する全ての次元に関して一括で情報を取得する方法もあります。
!> @param[in]  var           変数ハンドル
!> @param[in]  dimord        次元順序番号
!> @param[out] start         開始インデックス (省略可能)
!> @param[out] count         カウント (省略可能)
!> @param[out] stride        ストライド (省略可能)
!> @param[in]  count_compact 縮退次元を含むか (省略可能)
!> @endja
!>
subroutine gtvargetslice(var, dimord, start, count, stride, count_compact)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: gt_dimmap, map_lookup, dimord_skip_compact
  implicit none
  type(gt_variable), intent(in):: var
  integer, intent(in):: dimord
  integer, intent(out), optional:: start
  integer, intent(out), optional:: count
  integer, intent(out), optional:: stride
  logical, intent(in), optional:: count_compact
  type(gt_dimmap), allocatable:: map(:)
  integer:: vid, udimord, ndims
  logical:: allmode
continue
  allmode = .true.
  if (present(count_compact)) allmode = count_compact
  call map_lookup(var, vid=vid, ndims=ndims)
  if (vid < 0 .or. ndims <= 0) goto 999
  allocate(map(ndims))
  call map_lookup(var, map=map)
  if (allmode) then
    udimord = dimord
  else
    udimord = dimord_skip_compact(dimord, map)
  endif
  if (udimord < 1 .or. udimord > size(map)) goto 997
 
  if (present(start)) start = map(udimord)%start
  if (present(count)) count = map(udimord)%count
  if (present(stride)) stride = map(udimord)%stride
  deallocate(map)
  return
 
997 continue
  deallocate(map)
999 continue
  if (present(start)) start = -1
  if (present(count)) count = -1
  if (present(stride)) stride = -1
end subroutine gtvargetslice