gtvargetattrsc.f90

Go to the documentation of this file.

!> @file gtvargetattrsc.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Character type attribute input
!>
!> This subroutine is provided through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 文字型属性の入力
!>
!> このサブルーチンは gtdata_generic から提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Get character attribute value
!>
!> When receiving as character type, truncates or pads with blanks
!> to match the receiving variable's length, same as normal character
!> assignment. Uses default value if attribute does not exist.
!> @param[in]  var     Variable handle
!> @param[in]  name    Attribute name
!> @param[out] value   Retrieved attribute value
!> @param[in]  default Default value (optional)
!> @enden
!>
!> @ja
!> @brief 文字属性値を取得
!>
!> character 型で受け取る場合は通常の文字型代入と同様、
!> 受け側変数の長さに合わせて切り捨て・空白埋めを行う。
!> 属性が存在しない場合 default 値を使う。
!> @param[in]  var     変数ハンドル
!> @param[in]  name    属性名
!> @param[out] value   取得した属性値
!> @param[in]  default デフォルト値 (省略可能)
!> @endja
!>
subroutine gtvargetattrcc(var, name, value, default)
 
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: get_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_trace, only: beginsub, endsub
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(in):: var
  character(len = *), intent(in):: name
  character(len = *), intent(out):: value
  character(len = *), intent(in), optional:: default
  integer:: class, cid, stat
  character(len = string):: p_default
  character(len = *), parameter:: subnam = "gtvargetattrcc"
continue
  call beginsub(subnam)
  call var_class(var, class, cid)
  p_default = ""
  if (present(default)) p_default = default
  if (class == vtb_class_netcdf) then
    call get_attr(gd_nc_variable(cid), name, value, p_default, stat)
  endif
  call endsub(subnam, "%d:%d:%c = %c", i=(/class, cid/), &
    & c1=trim(name), c2=trim(value))
end subroutine gtvargetattrcc