gdncvarsearch.f90

Go to the documentation of this file.

!> @file gdncvarsearch.f90
!>
!> @author GFD Dennou Club
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Search for variables in a netCDF file
!>
!> To enumerate all variables in a file:
!> 1. Call var_search(iter, urlbase) to initialize the iterator
!> 2. Call attr_next(iter, url, end) in a loop
!> 3. url gives each variable URL; end becomes true when all variables are enumerated
!> @enden
!>
!> @ja
!> @brief netCDF ファイル内の変数を検索
!>
!> ファイル内の全変数を列挙するには:
!> 1. var_search(iter, urlbase) を呼び出してイテレータを初期化
!> 2. ループ内で attr_next(iter, url, end) を呼び出す
!> 3. url が各変数の URL を返し、全変数列挙完了時に end が真になる
!> @endja
!>
 
!>
!> @en
!> @brief Initialize variable search iterator
!> @enden
!>
!> @ja
!> @brief 変数検索イテレータを初期化
!> @endja
!>
!> @param[out] iter    @en Search iterator @enden @ja 検索イテレータ @endja
!> @param[in]  urlBase @en Base URL for the file @enden @ja ファイルのベース URL @endja
!>
subroutine gdncvarsearchinit(iter, urlBase)
  use dc_types, only: string
  use gtdata_netcdf_types, only: gd_nc_variable_search
  use dc_url, only: urlsplit
  use gtdata_netcdf_file_generic, only: gdncfileopen
  use dc_trace, only: beginsub, endsub, dbgmessage
  implicit none
  type(gd_nc_variable_search), intent(out):: iter
  character(len = *), intent(in):: urlBase
  character(len = string):: file
  logical:: err
  character(len = *), parameter:: subname = 'GDNcVarSearchInit'
 
  call beginsub(subname, 'urlbase=<%c>', c1=trim(urlbase))
  call urlsplit(trim(urlbase), file=file)
  call gdncfileopen(iter%fileid, filename=file, writable=.false., err=err)
  if (err) iter%fileid = -1
  iter%varid = 0
  iter%dimid = 0
  call endsub(subname, 'file=%d', i=(/iter%fileid/))
end subroutine gdncvarsearchinit
 
!>
!> @en
!> @brief Get next variable in search
!>
!> Returns the URL of the next variable. Dimension-only variables
!> (without corresponding coordinate variable) are also included.
!> @enden
!>
!> @ja
!> @brief 検索の次の変数を取得
!>
!> 次の変数の URL を返します。次元のみの変数
!> (対応する座標変数がないもの) も含まれます。
!> @endja
!>
!> @param[inout] iter @en Search iterator @enden @ja 検索イテレータ @endja
!> @param[out]   url  @en Variable URL @enden @ja 変数 URL @endja
!> @param[out]   end  @en True when all variables enumerated @enden
!>                    @ja 全変数列挙完了時に真 @endja
!>
subroutine gdncvarsearchnext(iter, url, end)
  use gtdata_netcdf_types, only: gd_nc_variable_search
  use dc_types, only: string
  use netcdf, only: nf90_max_name, nf90_noerr, &
    & nf90_inquire_variable, nf90_inquire_dimension, nf90_inq_varid
  use dc_url, only: urlmerge
  use gtdata_netcdf_file_generic, only: gdncfileinquire, gdncfileclose
  use dc_trace, only: beginsub, endsub, dbgmessage
  implicit none
  type(gd_nc_variable_search), intent(inout):: iter
  character(len = *), intent(out):: url
  logical, intent(out):: end
  character(len = string):: filename
  character(len = NF90_MAX_NAME):: varname
  integer:: stat, varid_tmp
  character(len = *), parameter:: subname = 'GDNcVarSearchNext'
continue
  call beginsub(subname)
  if (iter%fileid <= 0) then
    end = .TRUE.
    url = ''
    call endsub(subname, "bad file %d", i=(/iter%fileid/))
    return
  endif
  if (iter%varid >= 0) then
    iter%varid = iter%varid + 1
    stat = nf90_inquire_variable(iter%fileid, iter%varid, name = varname)
    if (stat == nf90_noerr) goto 900
    iter%varid = -1
  endif
  do while (iter%dimid >= 0)
    iter%dimid = iter%dimid + 1
    ! --- 指定番号の次元がなければエラー ---
    stat = nf90_inquire_dimension(iter%fileid, iter%dimid, name = varname)
    if (stat /= nf90_noerr) exit
    ! --- 指定番号の次元と同名の変数があれば却下、次番号へ ---
    stat = nf90_inq_varid(iter%fileid, varname, varid_tmp)
    if (stat /= nf90_noerr) goto 900
  enddo
  end = .TRUE.
  url = ""
  call gdncfileclose(iter%fileid)
  iter%dimid = -1
  call endsub(subname, "end file %d", i=(/iter%fileid/))
  return
 
900 continue
  call gdncfileinquire(iter%fileid, name=filename)
  url = urlmerge(file=trim(filename), var=trim(varname))
  end = .FALSE.
  call endsub(subname, "file=%d url=<%c>", &
    & i=(/iter%fileid/), c1=trim(url))
  return
end subroutine gdncvarsearchnext