gdncvarputattrreal.f90

Go to the documentation of this file.

!> @file gdncvarputattrreal.f90
!>
!> @author GFD Dennou Club
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Put real/double attribute to netCDF variable
!> @enden
!>
!> @ja
!> @brief netCDF 変数に実数/倍精度属性を設定
!> @endja
!>
 
!>
!> @en
!> @brief Set real (single precision) attribute value
!>
!> Sets a real attribute on a variable. If name starts with '+',
!> it is treated as a global attribute. Empty value array deletes the attribute.
!> @enden
!>
!> @ja
!> @brief 実数 (単精度) 属性値を設定
!>
!> 変数に実数属性を設定します。name が '+' で始まる場合、
!> グローバル属性として扱われます。空の value 配列は属性を削除します。
!> @endja
!>
!> @param[in]  var   @en Variable handle @enden @ja 変数ハンドル @endja
!> @param[in]  name  @en Attribute name @enden @ja 属性名 @endja
!> @param[in]  value @en Real values to set @enden @ja 設定する実数値 @endja
!> @param[out] err   @en Error flag (optional) @enden @ja エラーフラグ (省略可能) @endja
!>
subroutine gdncvarputattrreal(var, name, value, err)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_entry
  use gtdata_netcdf_file_generic, only: gdncfiledefinemode
  use gtdata_netcdf_internal, only: vtable_lookup
  use netcdf, only: &
    & nf90_global, &
    & nf90_noerr, &
    & nf90_put_att, &
    & nf90_del_att
  use dc_url, only: gt_plus
  use dc_error
  implicit none
  type(gd_nc_variable), intent(in):: var
  character(len = *), intent(in):: name
  real, intent(in):: value(:)
  logical, intent(out), optional:: err
  type(gd_nc_variable_entry):: ent
  integer:: stat
  continue
  stat = vtable_lookup(var, ent)
  if (stat /= nf90_noerr) goto 999
  if (size(value) == 0) then
    if (name(1:1) == gt_plus) then
      stat = nf90_del_att(ent%fileid, nf90_global, name(2:))
    else
      stat = nf90_del_att(ent%fileid, ent%varid, name)
    endif
    goto 999
  endif
  stat = gdncfiledefinemode(ent%fileid)
  if (stat /= nf90_noerr) goto 999
  if (name(1:1) == gt_plus) then
    stat = nf90_put_att(ent%fileid, nf90_global, name(2:), value)
  else
    stat = nf90_put_att(ent%fileid, ent%varid, name, value)
  endif
999 continue
  call storeerror(stat, 'GDNcVarPutAttrReal', err)
end subroutine gdncvarputattrreal
 
!>
!> @en
!> @brief Set double precision attribute value
!>
!> Sets a double precision attribute on a variable. If name starts with '+',
!> it is treated as a global attribute. Empty value array deletes the attribute.
!> @enden
!>
!> @ja
!> @brief 倍精度属性値を設定
!>
!> 変数に倍精度属性を設定します。name が '+' で始まる場合、
!> グローバル属性として扱われます。空の value 配列は属性を削除します。
!> @endja
!>
!> @param[in]  var   @en Variable handle @enden @ja 変数ハンドル @endja
!> @param[in]  name  @en Attribute name @enden @ja 属性名 @endja
!> @param[in]  value @en Double precision values to set @enden @ja 設定する倍精度値 @endja
!> @param[out] err   @en Error flag (optional) @enden @ja エラーフラグ (省略可能) @endja
!>
subroutine gdncvarputattrdouble(var, name, value, err)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_entry
  use gtdata_netcdf_internal, only: vtable_lookup
  use gtdata_netcdf_file_generic, only: gdncfiledefinemode
  use netcdf, only: &
    & nf90_global, &
    & nf90_noerr, &
    & nf90_put_att, &
    & nf90_del_att
  use dc_url, only: gt_plus
  use dc_error
  implicit none
  type(gd_nc_variable), intent(in):: var
  character(len = *), intent(in):: name
  double precision, intent(in):: value(:)
  logical, intent(out), optional:: err
  type(gd_nc_variable_entry):: ent
  integer:: stat
  continue
  stat = vtable_lookup(var, ent)
  if (stat /= 0) goto 999
  if (size(value) == 0) then
    if (name(1:1) == gt_plus) then
      stat = nf90_del_att(ent%fileid, nf90_global, name(2:))
    else
      stat = nf90_del_att(ent%fileid, ent%varid, name)
    endif
    goto 999
  endif
  stat = gdncfiledefinemode(ent%fileid)
  if (stat /= nf90_noerr) goto 999
  if (name(1:1) == gt_plus) then
    stat = nf90_put_att(ent%fileid, nf90_global, name(2:), value)
  else
    stat = nf90_put_att(ent%fileid, ent%varid, name, value)
  endif
999 continue
  call storeerror(stat, 'GDNcVarPutAttrDouble', err)
end subroutine