gdncattrinquire.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!> @file gdncattrinquire.f90
!>
!> @author GFD Dennou Club
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Inquire attribute information
!> @enden
!>
!> @ja
!> @brief 属性情報の問い合わせ
!> @endja
!>
 
!>
!> @en
!> @brief Get attribute type information
!>
!> Returns the type name of the specified attribute.
!> @enden
!>
!> @ja
!> @brief 属性の型情報を取得
!>
!> 指定された属性の型名を返します。
!> @endja
!>
!> @param[in]  var      @en Variable handle @enden @ja 変数ハンドル @endja
!> @param[in]  attrname @en Attribute name @enden @ja 属性名 @endja
!> @param[out] xtype    @en Type name (optional) @enden @ja 型名 (省略可能) @endja
!>
subroutine gdncattrinquire(var, attrname, xtype)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_entry
  use gtdata_netcdf_internal, only: vtable_lookup
  use gtdata_netcdf_generic, only: gdncxtypename, inquireplus
  use netcdf, only: nf90_max_name, nf90_noerr, nf90_inquire_attribute
  implicit none
  type(gd_nc_variable), intent(in):: var
  character(len=*), intent(in):: attrname
  character(len=*), intent(out), optional:: xtype
  type(gd_nc_variable_entry):: ent
  integer:: varid, i_xtype, stat
  character(len=NF90_MAX_NAME):: anam
  stat = vtable_lookup(var, ent)
  if (stat /= nf90_noerr) return
  if (present(xtype)) then
    call inquireplus(var, attrname, varid, anam)
    stat = nf90_inquire_attribute(ent%fileid, varid, anam, xtype=i_xtype)
    if (stat /= nf90_noerr) i_xtype = 0
    call gdncxtypename(i_xtype, xtype)
  endif
end subroutine
 
!>
!> @en
!> @brief Get actual varid and attribute name for netCDF access
!>
!> Determines the actual varid and attribute name to use for netCDF access:
!> - If attrname starts with '+': Force global attribute
!> - If attrname starts with '-': Search variable attribute, then global
!> @enden
!>
!> @ja
!> @brief netCDF アクセス用の実際の varid と属性名を取得
!>
!> netCDF アクセスに使う実際の varid と属性名を決定します:
!> - attrname の先頭が '+': グローバル属性を強制指示
!> - attrname の先頭が '-': 変数属性、グローバル属性の順で検索
!> @endja
!>
!> @param[in]  var         @en Variable handle @enden @ja 変数ハンドル @endja
!> @param[in]  attrname    @en Attribute name (may have prefix) @enden @ja 属性名 (接頭辞を含む場合あり) @endja
!> @param[out] varid       @en netCDF variable ID @enden @ja netCDF 変数 ID @endja
!> @param[out] nf_attrname @en netCDF attribute name @enden @ja netCDF 属性名 @endja
!>
subroutine gdncattrinquireplus(var, attrname, varid, nf_attrname)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_entry
  use gtdata_netcdf_internal, only: vtable_lookup
  use dc_url, only: gt_plus
  use netcdf, only: nf90_global, nf90_noerr, nf90_inquire_attribute
  type(gd_nc_variable), intent(in):: var
  character(len=*), intent(in):: attrname
  integer, intent(out):: varid
  type(gd_nc_variable_entry):: ent
  character(len=*), intent(out):: nf_attrname
  integer:: stat, n
  stat = vtable_lookup(var, ent)
  if (stat /= nf90_noerr) return
  if (attrname(1:1) == gt_plus) then
    varid = nf90_global
    nf_attrname = attrname(2: )
  else if (attrname(1:1) == '-') then
    varid = ent%varid
    nf_attrname = attrname(2: )
    stat = nf90_inquire_attribute(ent%fileid, varid, nf_attrname, len = n)
    if (stat == nf90_noerr) return
    varid = nf90_global
  else
    varid = ent%varid
    nf_attrname = attrname
  endif
end subroutine gdncattrinquireplus