dcdatetimemod.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief User defined function "mod"
!> @details
!> This file contains implementation procedures of "mod" function
!> for dc_date_types#DC_DIFFTIME.
!> @enden
!>
!> @ja
!> @brief 利用者定義関数 mod の実体
!> @details
!> このファイルには dc_date_types#DC_DIFFTIME 用の "mod" 関数の
!> 実装手続きが含まれています。
!> @endja
!>
 
!> @en
!> @brief Return the remainder of division of two DC_DIFFTIME values
!> @details
!> Return the remainder when `diff1` is divided by `diff2`.
!>
!> @note Division involving mixed months and datetime may produce
!>       approximate results.
!>
!> @param[in] diff1 Dividend (time difference)
!> @param[in] diff2 Divisor (time difference)
!> @return Remainder of diff1 / diff2
!> @enden
!>
!> @ja
!> @brief 2つの DC_DIFFTIME 値の除算の余りを返す
!> @details
!> 引数 `diff1` を `diff2` で除算した際の余りを返します.
!>
!> @note 月差と日時の混在する除算は近似的結果になるおそれがあります
!>
!> @param[in] diff1 被除数 (日時差)
!> @param[in] diff2 除数 (日時差)
!> @return diff1 / diff2 の余り
!> @endja
function dcdatetime_mod_ff(diff1, diff2) result(result)
 
  use dc_date_internal, only: dcdate_normalize, dcdate_nondimcheck
  use dc_date_types, only: cyclic_mdays, dc_datetime, dc_difftime
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(==), operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modscl => mod, modulo, int, abs, sign
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff1, diff2
  type(dc_scaled_sec):: sec1, sec2
  type(dc_scaled_sec):: zero_sec
continue
  result % day_seconds = diff1 % day_seconds
  if (diff1 % day == zero_sec .and. diff2 % day == zero_sec .and. &
    & diff1 % sec == zero_sec .and. diff2 % sec == zero_sec) then
    result % mon = modscl(diff1 % mon, diff2 % mon)
    result % day = zero_sec
    result % sec = zero_sec
  else if (diff1 % sec == zero_sec .and. diff2 % sec == zero_sec) then
    result % mon = zero_sec
    result % day = modscl((cyclic_mdays * diff1 % mon + diff1 % day), &
      & (cyclic_mdays * diff2 % mon + diff2 % day))
    result % sec = zero_sec
  else
    sec1 = diff1 % day_seconds * (cyclic_mdays * diff1 % mon + diff1 % day) &
      & + diff1 % sec
    sec2 = diff2 % day_seconds * (cyclic_mdays * diff2 % mon + diff2 % day) &
      & + diff2 % sec
    result % sec = modscl(sec1, sec2)
    result % day = zero_sec
    result % mon = zero_sec
    call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
  endif
  call dcdate_nondimcheck('dc_date#mod', diff1, diff2, result)
end function dcdatetime_mod_ff