dcdatetimeeq.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Functions for user defined operation (==)
!> @details
!> Procedures described in this file are provided from "dc_date" module.
!> @enden
!>
!> @ja
!> @brief 利用者定義演算子 (==) のための関数
!> @details
!> このファイルに記載される手続き群は dc_date モジュールから提供されます.
!> @endja
!>
 
!> @en
!> @brief Compare two DC_DATETIME values for equality
!> @details
!> Compares two datetime arguments.
!> Returns `.true.` if the datetime stored in the first argument
!> is equal to the datetime stored in the second argument.
!>
!> @param[in] time1 First datetime
!> @param[in] time2 Second datetime
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief 2つの DC_DATETIME 値が等しいか比較
!> @details
!> 2 つの引数の日時を比較します.
!> 1 つ目の引数に格納される日時が 2 つ目の引数に格納される日時
!> と同じ場合, .true. が返ります.
!>
!> @param[in] time1 1つ目の日時
!> @param[in] time2 2つ目の日時
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_tt(time1, time2) result(result)
  use dc_date_generic, only: eval, evalsclsec, zonetodiff
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(==), operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), assignment(=)
  implicit none
  type(dc_datetime), intent(in):: time1, time2
  type(dc_scaled_sec):: year1, year2, time1_sec, time2_sec
continue
  call eval(time1, sclyear=year1)
  call eval(time2, sclyear=year2)
  time1_sec = evalsclsec(time1) + evalsclsec(zonetodiff(time1 % zone))
  time2_sec = evalsclsec(time2) + evalsclsec(zonetodiff(time2 % zone))
  if (year1 == year2 .and. time1_sec == time2_sec) then
    result = .true.
  else
    result = .false.
  end if
end function dcdatetime_eq_tt
 
 
!> @en
!> @brief Compare two DC_DIFFTIME values for equality
!> @details
!> Compares two time difference arguments.
!> Returns `.true.` if the time difference stored in the first argument
!> is equal to the time difference stored in the second argument.
!>
!> @param[in] diff1 First time difference
!> @param[in] diff2 Second time difference
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief 2つの DC_DIFFTIME 値が等しいか比較
!> @details
!> 2 つの引数の日時差を比較します.
!> 1 つ目の引数に格納される日時差が 2 つ目の引数に格納される日時差
!> と同じ場合, .true. が返ります.
!>
!> @param[in] diff1 1つ目の日時差
!> @param[in] diff2 2つ目の日時差
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_ff(diff1, diff2) result(result)
  use dc_scaledsec, only: operator(==)
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff1, diff2
continue
  if (       diff1 % mon == diff2 % mon &
    &  .and. diff1 % day == diff2 % day &
    &  .and. diff1 % sec == diff2 % sec   ) then
    result = .true.
  else
    result = .false.
  end if
end function dcdatetime_eq_ff
 
!> @en
!> @brief Compare integer with DC_DIFFTIME for equality
!> @details
!> Compares whether time difference `diff` equals `i`.
!> Returns `.true.` if `diff` converted to seconds equals `i`.
!>
!> @param[in] i Integer to compare
!> @param[in] diff Time difference
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief 整数と DC_DIFFTIME が等しいか比較
!> @details
!> 引数 `diff` の日時差が `i` と等しいかどうかを比較します. `diff`
!> を秒数に換算した値と `i` とが等しい場合, .true. が返ります.
!>
!> @param[in] i 比較する整数
!> @param[in] diff 日時差
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_if(i, diff) result(result)
  use dc_date_generic, only: operator(==)
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff
  integer, intent(in):: i
continue
  result = real(i) == diff
end function dcdatetime_eq_if
 
!> @en
!> @brief Compare DC_DIFFTIME with integer for equality
!> @param[in] diff Time difference
!> @param[in] i Integer to compare
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME と整数が等しいか比較
!> @param[in] diff 日時差
!> @param[in] i 比較する整数
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_fi(diff, i) result(result)
  use dc_date_generic, only: operator(==)
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff
  integer, intent(in):: i
continue
  result = i == diff
end function dcdatetime_eq_fi
 
!> @en
!> @brief Compare single precision real with DC_DIFFTIME for equality
!> @details
!> Compares whether time difference `diff` equals `r`.
!> Returns `.true.` if `diff` converted to seconds equals `r`.
!>
!> @param[in] r Real to compare
!> @param[in] diff Time difference
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief 単精度実数と DC_DIFFTIME が等しいか比較
!> @details
!> 引数 `diff` の日時差が `r` と等しいかどうかを比較します. `diff`
!> を秒数に換算した値と `r` とが等しい場合, .true. が返ります.
!>
!> @param[in] r 比較する実数
!> @param[in] diff 日時差
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_rf(r, diff) result(result)
  use dc_scaledsec, only: operator(==)
  use dc_date_generic, only: evalsclsec
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff
  real, intent(in):: r
continue
  if (evalsclsec(diff) == r) then
    result = .true.
  else
    result = .false.
  end if
end function dcdatetime_eq_rf
 
!> @en
!> @brief Compare DC_DIFFTIME with single precision real for equality
!> @param[in] diff Time difference
!> @param[in] r Real to compare
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME と単精度実数が等しいか比較
!> @param[in] diff 日時差
!> @param[in] r 比較する実数
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_fr(diff, r) result(result)
  use dc_date_generic, only: operator(==)
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff
  real, intent(in):: r
continue
  result = r == diff
end function dcdatetime_eq_fr
 
!> @en
!> @brief Compare double precision real with DC_DIFFTIME for equality
!> @details
!> Compares whether time difference `diff` equals `d`.
!> Returns `.true.` if `diff` converted to seconds equals `d`.
!>
!> @param[in] d Double precision real to compare
!> @param[in] diff Time difference
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief 倍精度実数と DC_DIFFTIME が等しいか比較
!> @details
!> 引数 `diff` の日時差が `d` と等しいかどうかを比較します. `diff`
!> を秒数に換算した値と `d` とが等しい場合, .true. が返ります.
!>
!> @param[in] d 比較する倍精度実数
!> @param[in] diff 日時差
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_df(d, diff) result(result)
  use dc_date_generic, only: evalsclsec
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(==)
  use dc_types, only: dp
  implicit none
  type(dc_difftime), intent(in):: diff
  real(dp), intent(in):: d
continue
  if (evalsclsec(diff) == d) then
    result = .true.
  else
    result = .false.
  end if
end function dcdatetime_eq_df
 
!> @en
!> @brief Compare DC_DIFFTIME with double precision real for equality
!> @param[in] diff Time difference
!> @param[in] d Double precision real to compare
!> @return result `.true.` if equal, `.false.` otherwise
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME と倍精度実数が等しいか比較
!> @param[in] diff 日時差
!> @param[in] d 比較する倍精度実数
!> @return result 等しい場合 .true., そうでなければ .false.
!> @endja
logical function dcdatetime_eq_fd(diff, d) result(result)
  use dc_date_generic, only: operator(==)
  use dc_types, only: dp
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff
  real(dp), intent(in):: d
continue
  result = d == diff
end function dcdatetime_eq_fd