dcdatetimediv.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Functions for user defined operation (/)
!> @details
!> Procedures described in this file are provided from "dc_date" module.
!> @enden
!>
!> @ja
!> @brief 利用者定義演算子 (/) のための関数
!> @details
!> このファイルに記載される手続き群は dc_date モジュールから提供されます.
!> @endja
!>
 
!> @en
!> @brief Divide DC_DIFFTIME by integer
!> @details
!> Returns the result of dividing time difference `diff` by `denominator`.
!>
!> **Note**: Dividing month difference may produce approximate results.
!>
!> @param[in] diff Time difference
!> @param[in] denominator Divisor (integer)
!> @return result Result of division
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME を整数で除算
!> @details
!> 日時差 `diff` を `denominator` で除算した結果を返します.
!>
!> **注意**: 月差を除算すると近似的結果になるおそれがあります
!>
!> @param[in] diff 日時差
!> @param[in] denominator 除数 (整数)
!> @return result 除算結果
!> @endja
function dcdatetime_div_fi(diff, denominator) result(result)
  use dc_date_types, only: cyclic_mdays
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modscl => mod, modulo, int, abs, sign
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  integer, intent(in):: denominator
continue
  result % mon = int( diff % mon / denominator )
  ! 月からの近似的繰り下がりは日単位でしか行わない
  result % day = &
    &   int( diff % day / denominator ) &
    & + int( (cyclic_mdays * modscl(diff % mon, denominator)) / denominator )
  result % sec = diff % sec / denominator + &
    & (diff % day_seconds * modscl(diff % day, denominator)) / &
    & denominator
  result % nondim_flag = diff % nondim_flag
end function dcdatetime_div_fi
 
!> @en
!> @brief Divide DC_DIFFTIME by single precision real
!> @details
!> **Note**: Dividing month difference may produce approximate results.
!>
!> @param[in] diff Time difference
!> @param[in] denominator Divisor (single precision)
!> @return result Result of division
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME を単精度実数で除算
!> @details
!> **注意**: 月差を除算すると近似的結果になるおそれがあります
!>
!> @param[in] diff 日時差
!> @param[in] denominator 除数 (単精度)
!> @return result 除算結果
!> @endja
function dcdatetime_div_fr(diff, denominator) result(result)
  use dc_date_generic, only: operator(/)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real, intent(in):: denominator
continue
  result = diff / real(denominator, dp)
end function dcdatetime_div_fr
 
!> @en
!> @brief Divide DC_DIFFTIME by double precision real
!> @details
!> **Note**: Dividing month difference may produce approximate results.
!>
!> @param[in] diff Time difference
!> @param[in] denominator Divisor (double precision)
!> @return result Result of division
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME を倍精度実数で除算
!> @details
!> **注意**: 月差を除算すると近似的結果になるおそれがあります
!>
!> @param[in] diff 日時差
!> @param[in] denominator 除数 (倍精度)
!> @return result 除算結果
!> @endja
function dcdatetime_div_fd(diff, denominator) result(result)
  use dc_date_internal, only: dcdate_normalize
  use dc_date_types, only: cyclic_mdays, dc_datetime, dc_difftime
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real(dp), intent(in):: denominator
  type(dc_scaled_sec):: month, day
continue
  month = int( diff % mon / denominator )
  result % mon = int(month)
  day =   int( diff % day / denominator ) &
    &   + int(cyclic_mdays * (month - result % mon))
  result % day = int(day)
  result % sec = &
    & diff % sec / denominator + (day - result % day) * diff % day_seconds
  result % day_seconds = diff % day_seconds
  result % nondim_flag = diff % nondim_flag
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_div_fd
 
!> @en
!> @brief Divide two DC_DIFFTIME values
!> @details
!> **Note**: Division mixing month difference and datetime may produce approximate results.
!>
!> @param[in] diff1 Dividend (time difference)
!> @param[in] diff2 Divisor (time difference)
!> @return result Result of division (double precision)
!> @enden
!>
!> @ja
!> @brief 2つの DC_DIFFTIME を除算
!> @details
!> **注意**: 月差と日時の混在する除算は近似的結果になるおそれがあります
!>
!> @param[in] diff1 被除数 (日時差)
!> @param[in] diff2 除数 (日時差)
!> @return result 除算結果 (倍精度)
!> @endja
function dcdatetime_div_ff(diff1, diff2) result(result)
  use dc_date_types, only: cyclic_mdays
  use dc_scaledsec, only: dc_scaled_sec, assignment(=), &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_types, only: dp
  implicit none
  real(dp):: result
  type(dc_difftime), intent(in):: diff1, diff2
continue
  ! ゼロ割対応コードが必要か?
  result = &
    & (diff1 % day_seconds * (cyclic_mdays * diff1 % mon + diff1 % day) &
    & + diff1 % sec) / &
    & (diff2 % day_seconds * (cyclic_mdays * diff2 % mon + diff2 % day) &
    & + diff2 % sec)
end function dcdatetime_div_ff