Functions/Subroutines
subroutine	dccaldateinquire1 (year, month, day, hour, min, sec, zone, elapse_sec, date, cal, err)
	Inquire information of date.
subroutine	dccaldateinquire2 (date_str, elapse_sec, date, cal, err)

Function/Subroutine Documentation

◆ dccaldateinquire1()

subroutine dccaldateinquire1	(	integer, intent(out), optional	year,
		integer, intent(out), optional	month,
		integer, intent(out), optional	day,
		integer, intent(out), optional	hour,
		integer, intent(out), optional	min,
		real(dp), intent(out), optional	sec,
		character(*), intent(out), optional	zone,
		real(dp), intent(in), optional	elapse_sec,
		type(dc_cal_date), intent(in), optional, target	date,
		type(dc_cal), intent(in), optional, target	cal,
		logical, intent(out), optional	err )

Inquire information of date.

Author: Yasuhiro MORIKAWA

Copyright: Copyright (C) GFD Dennou Club, 2009-2026. All rights reserved.
License is BSD-2-Clause. see COPYRIGHT in detail

Procedures described in this file are provided from "dc_calendar" module.

Inquire date information as individual variables

Inquire information of date.

If a string like as "YYYY-MM-DDThh:mm:ss.sTZD" (YYYY is year, MM is month, DD is day, hh is hour, mm is minute, ss.s is second, TZD is time zone) is needed, use a following homonymous subroutine.

If an optional argument date is omitted, information of date that is stored in the "dc_calendar" is returned, If date is not omitted, information of the variable is returned.

If an optional argument cal is omitted, information of calendar that is stored in the "dc_calendar" is used for conversion of elapsed seconds elapse_sec into year-month-day etc. If cal is not omitted, information of the variable is used.

Parameters

[out]	year	Year
[out]	month	Month
[out]	day	Day
[out]	hour	Hour
[out]	min	Minute
[out]	sec	Second
[out]	zone	Time-zone (difference from UTC)
[in]	elapse_sec	Elapsed seconds from date
[in]	date	An object that stores information of date and time
[in]	cal	An object that stores information of calendar
[out]	err	Exception handling flag. By default, when error occur in this procedure, the program aborts. If this err argument is given, .true. is substituted to err and the program does not abort.

Definition at line 94 of file dccaldateinquire.f90.

 
  use dc_calendar_types, only: dc_cal, dc_cal_date
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize
  use dc_calendar_generic, only: dccaldatetochar, dccaltochar
  use dc_message, only: messagenotify
  use dc_string, only: lchar
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit, &
    & dc_einconsistcaldate
  use dc_types, only: string, dp, token
  implicit none
  integer, intent(out), optional:: year
  integer, intent(out), optional:: month
  integer, intent(out), optional:: day
  integer, intent(out), optional:: hour
  integer, intent(out), optional:: min
  real(DP), intent(out), optional:: sec
  character(*), intent(out), optional:: zone
  real(DP), intent(in), optional:: elapse_sec
  type(DC_CAL_DATE), intent(in), optional, target:: date
  type(DC_CAL), intent(in), optional, target:: cal
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  integer:: wyear, wmonth, wday, whour, wmin
  real(DP):: wsec
  character(TOKEN):: wzone
  type(DC_CAL_DATE), pointer:: datep =>null()
  type(DC_CAL), pointer:: calp =>null()
  character(STRING):: e_date_str, e_cal_str
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalInquire1'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  if ( .not. datep % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL_DATE'
    goto 999
  end if
 
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  wyear  = datep % year
  wmonth = datep % month
  wday   = datep % day
  whour  = datep % hour
  wmin   = datep % min
  wsec   = datep % sec
  wzone  = datep % zone
 
  ! 経過時間(秒)の追加
  ! Add elapsed time (seconds)
  !
  if ( present( elapse_sec ) ) then
!!$    if ( elapse_sec < 0.0_DP ) then
!!$      stat = DC_ENEGATIVE
!!$      cause_c = 'elapse_sec'
!!$      goto 999
!!$    end if
 
    wsec = wsec + elapse_sec
  end if
 
  ! 日時の正規化
  ! Normalize date and time
  !
  stat = dccaldate_normalize( wyear, wmonth, wday, whour, wmin, wsec, & ! (inout)
    &                         calp )                                    ! (in)
  if ( stat == dc_einconsistcaldate ) then
    e_cal_str = dccaltochar( calp )
    e_date_str = dccaldatetochar( wyear, wmonth, wday, whour, wmin, wsec, wzone )
    call messagenotify('W', subname, 'cal=<%c> and date=<%c> are inconsistency', &
      & c1 = trim(e_cal_str), c2 = trim(e_date_str) )
    goto 999
  end if
 
  ! 引数への代入
  ! Substitute arguments
  !
  if ( present(year ) ) year  = wyear
  if ( present(month) ) month = wmonth
  if ( present(day  ) ) day   = wday
  if ( present(hour ) ) hour  = whour
  if ( present(min  ) ) min   = wmin
  if ( present(sec  ) ) sec   = wsec
  if ( present(zone ) ) zone  = wzone
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp, datep )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )

References dc_trace::beginsub(), dc_error::dc_einconsistcaldate, dc_error::dc_enotinit, dc_error::dc_noerr, dc_calendar_internal::dccaldate_normalize(), dc_calendar_internal::default_cal, dc_calendar_internal::default_cal_set(), dc_calendar_internal::default_date, dc_types::dp, dc_trace::endsub(), dc_error::storeerror(), dc_types::string, and dc_types::token.

Here is the call graph for this function:

◆ dccaldateinquire2()

subroutine dccaldateinquire2	(	character(*), intent(out)	date_str,
		real(dp), intent(in), optional	elapse_sec,
		type(dc_cal_date), intent(in), optional, target	date,
		type(dc_cal), intent(in), optional, target	cal,
		logical, intent(out), optional	err )

Inquire date information as a string

Inquire information of date. A result is returned as a string like as YYYY-MM-DDThh:mm:ss.sTZD (YYYY is year, MM is month, DD is day, hh is hour, mm is minute, ss.s is second, TZD is time zone). Format of date is conformed to gtool4 netCDF Convention "5.5 Expression of date and time"

If individual variables (year, month, day, hour, minute, second, zone) are needed, use a foregoing homonymous subroutine.