*"表題 第２次元の結合 GTOOL3(GPYCOM)
*
*"履歴 90/08/19 沼口  敦
*
*
*********************************************************************
*"         << 第２次元の結合 >>
*********************************************************************
      SUBROUTINE GPYCOM
     I         ( HHEAD , GDATA , IY    ,
     M           HHEADO, GDATAO         )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IY                      !" 入れるべき第2次元の格
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
*"         < 1. 大きさの取得 >
*
      CALL GUSMIS ( HHEADO )
*
      CALL GUQSIZ
     I         ( HHEADO,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR , IZEND , IZDIM  )
*
      CALL GUSZCK ( HHEADO, IXDIM*IYDIM*IZDIM )
*
      IF ( ( IY .LT. IYSTR ) .OR. ( IY .GT. IYEND ) ) THEN
         CALL MSGDMP( 'E', 'GPYCOM', 'IY IS OUT OF RANGE.' )
      ENDIF
*
*"         < 2. データ詰め替え >
*
      DO 2100 IZ = 1, IZDIM
         CALL VRSET
     I      ( GDATA ( IXDIM*(IZ-1) + 1 ),
     O        GDATAO( IXDIM*IYDIM*(IZ-1) + IXDIM*(IY-IYSTR) + 1 ),
     I        IXDIM, 1     , 1                                     )
 2100 CONTINUE
*
      RETURN
      END
*********************************************************************
*"         << 第２次元の結合の準備 >>
*********************************************************************
      SUBROUTINE GPYCMI
     I         ( HHEAD , HAITMY, IYSTR , IYEND ,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      CHARACTER  HAITMY      *(*)        !" 結合する第2次元の軸の
      INTEGER    IYSTR                   !" 第2次元の軸の格子始め
      INTEGER    IYEND                   !" 第2次元の軸の格子終り
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      LOGICAL    OCYCL                   !" サイクリックか？
      CHARACTER  HAITM       *(NCC)
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
*
*"         < 1. 大きさの取得 >
*
      CALL GHCGET ( HHEAD , 'AITM2', HAITM  )
      IF ( HAITM .NE. ' ' ) THEN
         CALL GUQSIZ
     I         ( HHEAD ,
     O           IXSTR , IXEND , IXDIM ,
     O           IZSTR , IZEND , IZDIM ,
     O           IDUMY1, IDUMY2, IDUMY3 )
      ELSE
         CALL GUQSIZ
     I         ( HHEAD ,
     O           IXSTR , IXEND , IXDIM ,
     O           IDUMY1, IDUMY2, IDUMY3,
     O           IZSTR , IZEND , IZDIM  )
      ENDIF
*
      IF ( ( IYSTR .EQ. 0 ) .AND. ( IYEND .EQ. 0 ) ) THEN
         CALL GUQAXD
     I         ( HAITMY,
     O           IADIM , OCYCL  )
         IYSTRZ = 1
         IYENDZ = IADIM
      ELSE
         IYSTRZ = IYSTR
         IYENDZ = IYEND
      ENDIF
*
      IYDIM = IYENDZ - IYSTRZ + 1
      CALL GUSZCK ( HHEADO, IXDIM*IYDIM*IZDIM )
*
*"         < 2. 欠損値を詰める >
*
      CALL GHPGET ( HHEAD, 'MISS', VMISS )
      CALL RSET   ( GDATAO, IXDIM*IYDIM*IZDIM, 1 , VMISS )
*
*"         < 3. ヘッダー変更 >
*
      CALL GHCOPY ( HHEAD, HHEADO )
      CALL GHCGET ( HHEAD , 'AITM2', HAITM  )
      IF ( HAITM .NE. ' ' ) THEN
         CALL GHCGET ( HHEAD , 'AITM2', HAITM  )
         CALL GHCSET ( HHEADO, 'AITM3', HAITM  )
         CALL GHPSET ( HHEADO, 'ASTR3', IZSTR  )
         CALL GHPSET ( HHEADO, 'AEND3', IZEND  )
      ENDIF
*
      CALL GHCSET ( HHEADO, 'AITM2', HAITMY )
      CALL GHPSET ( HHEADO, 'ASTR2', IYSTRZ )
      CALL GHPSET ( HHEADO, 'AEND2', IYENDZ )
*
      IF ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAITMY, 'YC'   , '-combine',
     I                 IYSTRZ, IYENDZ ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
