*"表題 編集記述子セット GTOOL3(GHESET)
*
*"履歴 90/09/08 沼口  敦
*
*
********************************************************************
*"         << 編集記述子のセット >>
********************************************************************
      SUBROUTINE GHESET
     M         ( HHEAD ,
     I           HEDIT , HETTL, IENUM  )
*
      CHARACTER  HHEAD ( * )*(*)         !" ヘッダー
      CHARACTER  HEDIT *(*)              !" 編集略記号
      CHARACTER  HETTL *(*)              !" 編集タイトル
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC, NED
#else
#include         "gzsize.F"              !" NCC, NDC, NED
#endif
      CHARACTER  HP    *8                !" ヘッダーの欄指定
*
      IF ( ( IENUM .LT. 1 ).OR.( IENUM .GT. NED ) ) THEN
         CALL MSGDMP( 'W', 'GHESET', 'IRREGAL NUMBER EDIT FIELD.' )
         RETURN
      ENDIF
*
      HP = 'EDIT'
      WRITE ( HP(5:5),'(I1)' ) IENUM
      CALL GHCSET( HHEAD , HP  , HEDIT )
      HP(1:4) = 'ETTL'
      CALL GHCSET( HHEAD , HP  , HETTL )
*
      RETURN
      END
*********************************************************************
*"         << 編集記述子の追加セット >>
*********************************************************************
      SUBROUTINE GHEADD
     M         ( HHEAD ,
     I           HEDIT , HETTL )
*
      CHARACTER  HHEAD ( * )*(*)         !" ヘッダー
      CHARACTER  HEDIT *(*)              !" 編集略記号
      CHARACTER  HETTL *(*)              !" 編集タイトル
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC, NED
#else
#include         "gzsize.F"              !" NCC, NDC, NED
#endif
*
      CALL GHQENM ( HHEAD, IENUM )
*
      IF ( IENUM .GE. NED ) THEN
         CALL MSGDMP('W', 'GHEADD', 'NO MORE EDIT FIELD.' )
         RETURN
      ENDIF
*
      CALL       GHESET
     M         ( HHEAD ,
     I           HEDIT , HETTL, IENUM+1 )
*
      RETURN
*===================================================================
*"         << 編集記述子の再セット >>
*===================================================================
      ENTRY      GHERST
     M         ( HHEAD ,
     I           HEDIT , HETTL )
*
      CALL GHQENM ( HHEAD, IENUM )
*
      CALL       GHESET
     M         ( HHEAD ,
     I           HEDIT , HETTL, IENUM  )
*
      RETURN
      END
