*"表題 時刻をパック/アンパック GTOOL3(GHHGET)
*
*"履歴 90/08/21 沼口  敦
*
*
***********************************************************************
*"         << 時刻をパック >>
*********************************************************************
      SUBROUTINE GUTPAC
     I         ( IYEAR , IMONTH, IDAY  ,
     I           IHOUR , IMIN  , ISEC  ,
     O           HDATE                  )
*
      INTEGER    IYEAR                        !" 年
      INTEGER    IMONTH                       !" 月
      INTEGER    IDAY                         !" 日
      INTEGER    IHOUR                        !" 時
      INTEGER    IMIN                         !" 分
      INTEGER    ISEC                         !" 秒
      CHARACTER  HDATE *(*)                   !" 時刻(yyyymmddhhmmss)
*
      IF ( LEN( HDATE ) .LT. 14  ) THEN
         CALL MSGDMP( 'W', 'GUTPAC', 'SIZE OF HDATE IS TOO SMALL.' )
         RETURN
      ENDIF
*
      HDATE = ' '
      WRITE ( HDATE(1:4)  , '(I4)'   ) IYEAR
      WRITE ( HDATE(5:6)  , '(I2.2)' ) IMONTH
      WRITE ( HDATE(7:8)  , '(I2.2)' ) IDAY
      WRITE ( HDATE(9:10) , '(I2.2)' ) IHOUR
      WRITE ( HDATE(11:12), '(I2.2)' ) IMIN
      WRITE ( HDATE(13:14), '(I2.2)' ) ISEC
*
      RETURN
*======================================================================
*"         << 時刻をアンパック >>
*======================================================================
      ENTRY      GUTUPC
     O         ( IYEAR , IMONTH, IDAY  ,
     O           IHOUR , IMIN  , ISEC  ,
     I           HDATE                  )
*
      IF ( LEN( HDATE ) .LT. 14  ) THEN
         CALL MSGDMP( 'W', 'GUTUPC', 'SIZE OF HDATE IS TOO SMALL.' )
         RETURN
      ENDIF
*
      READ  ( HDATE(1:4)  , '(I4)', ERR=2900 ) IYEAR
      READ  ( HDATE(5:6)  , '(I2)', ERR=2900 ) IMONTH
      READ  ( HDATE(7:8)  , '(I2)', ERR=2900 ) IDAY
      READ  ( HDATE(9:10) , '(I2)', ERR=2900 ) IHOUR
      READ  ( HDATE(11:12), '(I2)', ERR=2900 ) IMIN
      READ  ( HDATE(13:14), '(I2)', ERR=2900 ) ISEC
*
      RETURN
*
 2900 CONTINUE
      CALL MSGDMP( 'W', 'GUTUPC', ' IRREGAL CONTENTS OF HDATE.' )
*
      RETURN
      END
