*"表題 時刻の参照 GTOOL3(GUQTIM)
*
*"履歴 90/09/15 沼口  敦
*"     96/03/06 竹広真一  無次元時間に対応. 
*"                        時間単位が STEP の場合は 
*"                        TDUR ステップを 1 無次元時間とする.
*
*********************************************************************
*"         << 時刻の参照 >>
*********************************************************************
      SUBROUTINE GUQTIM
     I         ( HHEAD ,
     O           RT    , HUTIM )
*
      CHARACTER  HHEAD ( * )*(*)         !" ヘッダー
      REAL       RT                      !" 時刻
      CHARACTER  HUTIM      *(*)         !" 時刻単位
*
      CHARACTER  HUTIMF     *8           !" 標準時間単位
      INTEGER    ITIME                   !" 時間単位, ステップ数
      INTEGER    ITIMEF                  !" 代表時間(無次元時間)
*
      CALL GHPGET ( HHEAD, 'TIME',  ITIME  )
      CALL GHCGET ( HHEAD, 'UTIM',  HUTIMF )

      IF ( HUTIMF(1:4) .EQ. 'STEP' )THEN
         CALL GHPGET ( HHEAD, 'TDUR',  ITIMEF  ) !" 1 無次元時間のステップ数
         RT = ITIME / REAL(ITIMEF)
         HUTIM = 'NDT'
      ELSE
         CALL GTCGET ( 'UTIM', HUTIM )
         CALL GUCT2R
     I            ( ITIME , HUTIMF, HUTIM , 1      ,
     O              RT                                )
      ENDIF
*
      RETURN
      END
