*"表題 第３次元の格子選択 GTOOL3(GPZSEL)
*
*"履歴 90/08/17 沼口  敦
*
*
*********************************************************************
*"         << 第３次元の格子選択 >>
*********************************************************************
      SUBROUTINE GPZSEL
     I         ( HHEAD , GDATA , IZSEL  ,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO          )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IZSEL                   !" 選択する第3次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HAXIS       *(NCC)
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
      LOGICAL    OCYCL                   !" サイクリックか？
*
*"         < 1. 大きさの取得 >
*
      CALL GUSMIS ( HHEAD )
*
      CALL GUQSIZ
     I         ( HHEAD ,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR , IZEND , IZDIM  )
*
      CALL GUSZCK ( HHEADO, IXDIM*IYDIM )
*
      CALL GHCGET( HHEAD, 'AITM3', HAXIS )
      CALL GUQAXD
     I         ( HAXIS ,
     O           IADIM , OCYCL  )
*
*"         < 2. データ詰め替え >
*
      CALL GHPGET ( HHEAD, 'MISS', VMISS )
*
      IF ( OCYCL ) THEN
         IZI = MOD( IZSEL-IZSTR, IADIM ) + 1
      ELSE
         IZI = IZSEL-IZSTR+1
      ENDIF
*
      IF ( ( 1.LE.IZI ).AND.( IZI.LE.IZDIM ) ) THEN
         CALL VRSET
     I      ( GDATA ( IXDIM*IYDIM*(IZI-1) + 1 ),
     O        GDATAO ,
     I        IXDIM*IYDIM  , 1    , 1                 )
      ELSE
         CALL GHPGET( HHEAD , 'MISS', VMISS )
         CALL RSET  ( GDATAO, IXDIM*IYDIM, VMISS )
      ENDIF
*
*"         < 3. ヘッダー変更 >
*
      CALL GHCOPY ( HHEAD, HHEADO )
      CALL GHCSET ( HHEADO, 'AITM3', ' '    )
      CALL GHPSET ( HHEADO, 'ASTR3', 1      )
      CALL GHPSET ( HHEADO, 'AEND3', 1      )
*
      IF ( ( IZSTR .EQ. IZSEL ).AND.( IZEND .EQ. IZSEL ) ) RETURN
*
      IF      ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAXIS , 'ZS'   , '-select',
     I                 IZSEL , IZSEL  ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
*********************************************************************
*"         << 第３次元の格子選択 >>
*********************************************************************
      SUBROUTINE GMZSEL
     M         ( HHEAD , GDATA ,
     I           IZSEL ,
     I           HEDIT , HETTL  )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IZSEL                   !" 選択する第3次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
*
      COMMON     /GMWORK/ GDATAW
      REAL       GDATAW ( 1 )            !" データ(ワーク)
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HHEADW ( NDC )*(NCC)    !" ヘッダー(ワーク)
*
      CALL       GMCSIZ ( HHEADW )
      CALL       GPZSEL
     I         ( HHEAD , GDATA , IZSEL  ,
     I           HEDIT , HETTL ,
     O           HHEADW, GDATAW          )
*
      CALL       GPFSET
     I         ( HHEADW, GDATAW,
     I           ' '   , ' '   ,
     O           HHEAD , GDATA   )
*
      RETURN
      END
