*"表題 第３次元の結合 GTOOL3(GPZCOM)
*
*"履歴 90/08/19 沼口  敦
*
*
*********************************************************************
*"         << 第３次元の結合 >>
*********************************************************************
      SUBROUTINE GPZCOM
     I         ( HHEAD , GDATA , IZ    ,
     M           HHEADO, GDATAO         )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IZ                      !" 入れるべき第3次元の格
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
*"         < 1. 大きさの取得 >
*
      CALL GUSMIS ( HHEADO )
*
      CALL GUQSIZ
     I         ( HHEADO,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR , IZEND , IZDIM  )
*
      CALL GUSZCK ( HHEADO, IXDIM*IYDIM*IZDIM )
*
      IF ( ( IZ .LT. IZSTR ) .OR. ( IZ .GT. IZEND ) ) THEN
         CALL MSGDMP( 'E', 'GPZCOM', 'IZ IS OUT OF RANGE.' )
      ENDIF
*
*"         < 2. データ詰め替え >
*
      CALL VRSET
     I     ( GDATA,
     O       GDATAO( IXDIM*IYDIM*(IZ-IZSTR) + 1 ),
     I       IXDIM*IYDIM  , 1     , 1          )
*
      RETURN
      END
*********************************************************************
*"         << 第３次元の結合の準備 >>
*********************************************************************
      SUBROUTINE GPZCMI
     I         ( HHEAD , HAITMZ, IZSTR , IZEND ,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      CHARACTER  HAITMZ      *(*)        !" 結合する第3次元の軸の
      INTEGER    IZSTR                   !" 第3次元の軸の格子始め
      INTEGER    IZEND                   !" 第3次元の軸の格子終り
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      LOGICAL    OCYCL                   !" サイクリックか？
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
*
*"         < 1. 大きさの取得 >
*
      CALL GUQSIZ
     I         ( HHEAD ,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IDUMY1, IDUMY2, IDUMY3 )
*
      IF ( ( IZSTR .EQ. 0 ) .AND. ( IZEND .EQ. 0 ) ) THEN
         CALL GUQAXD
     I         ( HAITMZ,
     O           IADIM , OCYCL  )
         IZSTRZ = 1
         IZENDZ = IADIM
      ELSE
         IZSTRZ = IZSTR
         IZENDZ = IZEND
      ENDIF
*
      IZDIM = IZENDZ - IZSTRZ + 1
      CALL GUSZCK ( HHEADO, IXDIM*IYDIM*IZDIM )
*
*"         < 2. 欠損値を詰める >
*
      CALL GHPGET ( HHEAD, 'MISS', VMISS )
      CALL RSET   ( GDATAO, IXDIM*IYDIM*IZDIM, 1 , VMISS )
*
*"         < 3. ヘッダー変更 >
*
      CALL GHCOPY ( HHEAD, HHEADO )
      CALL GHCSET ( HHEADO, 'AITM3', HAITMZ )
      CALL GHPSET ( HHEADO, 'ASTR3', IZSTRZ )
      CALL GHPSET ( HHEADO, 'AEND3', IZENDZ )
*
      IF ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAITMZ, 'ZC'   , '-combine',
     I                 IZSTRZ, IZENDZ ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
