*"表題 ファイル入出力時間設定付 GTOOL3(GXRDTS)
*
*"履歴 90/10/13 沼口  敦
*
*
*********************************************************************
*"         << GTOOL3標準フォーマット入力時間取得 >>
*********************************************************************
      SUBROUTINE GFRDTS
     O         ( HHEAD , GDATA , IEOD  ,
     O           IT    , IDATE , IDNUM , ITDUR ,
     I           HPSEL , HSEL  , ISEL  ,
     I           IFILE , IOMODE                 )
*
      CHARACTER  HHEAD ( * )*(*)             !" ヘッダー
      REAL       GDATA ( * )                 !" データ
      INTEGER    IEOD                        !" データ有：０ 無：１
      INTEGER    IT                          !" 通し時間
      INTEGER    IDATE ( * )                 !" 時刻：年月日時分秒
      INTEGER    IDNUM                       !" データ番号
      INTEGER    ITDUR                       !" 代表時間
      CHARACTER  HPSEL *(*)                  !" 選択する欄
      CHARACTER  HSEL  *(*)                  !" 選択するデータ(文
*    (INTEGER)   ISEL                        !" 選択するデータ(数
      INTEGER    IFILE                       !" 入力ファイル番号
      INTEGER    JFILE                       !" 出力ファイル番号
      INTEGER    IOMODE                      !" 入出力モード
      INTEGER    NOEND                       !" ENDFILE間隔
*
#ifdef SYS_IBMS
      INCLUDE   (GZSIZE)                     !" 文字数
#else
#include        "gzsize.F"                   !" 文字数
#endif
      CHARACTER  HDATE         *(NCC)        !" 日付
*
*"         < 1. 読み込み >
*
      CALL GFRDSL
     O            ( HHEAD , GDATA  , IEOD  ,
     I              HPSEL , HSEL   , ISEL  ,
     I              IFILE , IOMODE          )
*
      IF ( IEOD .NE. 0 ) RETURN
*
*"         < 2. ヘッダーからの取得 >
*
      CALL GHPGET ( HHEAD, 'TIME', IT    )
      CALL GHCGET ( HHEAD, 'DATE', HDATE )
      CALL GHPGET ( HHEAD, 'DNUM', IDNUM )
      CALL GHPGET ( HHEAD, 'TDUR', ITDUR )
*
      CALL GUTUPC
     O            ( IDATE(1), IDATE(2), IDATE(3),
     O              IDATE(4), IDATE(5), IDATE(6),
     I              HDATE                        )
*
      RETURN
*=======================================================================
*"         << GTOOL3標準フォーマット時間設定出力 >>
*=======================================================================
      ENTRY      GFWTTS
     I         ( HHEAD , GDATA ,
     I           IT    , IDATE , IDNUM , ITDUR ,
     I           JFILE , IOMODE, NOEND           )
*
      CALL GUTPAC
     I            ( IDATE(1), IDATE(2), IDATE(3),
     I              IDATE(4), IDATE(5), IDATE(6),
     O              HDATE                        )
*
      CALL GHPSET ( HHEAD , 'TIME' , IT     )
      CALL GHCSET ( HHEAD , 'DATE' , HDATE  )
      CALL GHPSET ( HHEAD , 'DNUM' , IDNUM  )
      CALL GHPSET ( HHEAD , 'TDUR' , ITDUR  )
*
      CALL GFWRIT
     I            ( HHEAD , GDATA  ,
     I              JFILE , IOMODE , NOEND   )
*
      RETURN
      END
